From cfbd8973d5ebc4db08609b1781110ee4ce6df1cc Mon Sep 17 00:00:00 2001
From: Kolan Sh <backbone@backbone.ws>
Date: Thu, 12 Nov 2020 15:27:06 +0300
Subject: [PATCH] tortoisehg-5.6 added

---
 dev-vcs/tortoisehg/Manifest              |  1 +
 dev-vcs/tortoisehg/tortoisehg-5.6.ebuild | 62 ++++++++++++++++++++++++
 2 files changed, 63 insertions(+)
 create mode 100644 dev-vcs/tortoisehg/Manifest
 create mode 100644 dev-vcs/tortoisehg/tortoisehg-5.6.ebuild

diff --git a/dev-vcs/tortoisehg/Manifest b/dev-vcs/tortoisehg/Manifest
new file mode 100644
index 00000000..108374b4
--- /dev/null
+++ b/dev-vcs/tortoisehg/Manifest
@@ -0,0 +1 @@
+DIST tortoisehg-5.6.tar.gz 8920111 SHA256 f925f6df0215588fa2ddfcefa4a94d1a2e0a6503743f0af8beef7184a4532b0c SHA512 30013a776ea7e8b1167280350b64a993ebccbf82486f93164a1eaa42e98587719503c3dd939f9ea682d4302532216575ad7a20e9e2122315f63af7d002d08b03 WHIRLPOOL 65462050d2a4f5c85b2f2f906934c097b512708cbbad7f87f845809382a5e6f9e1df7d0695cb71780f057ba975961faf5338c46fd6d913f3b2055cc064026579
diff --git a/dev-vcs/tortoisehg/tortoisehg-5.6.ebuild b/dev-vcs/tortoisehg/tortoisehg-5.6.ebuild
new file mode 100644
index 00000000..b8183d3e
--- /dev/null
+++ b/dev-vcs/tortoisehg/tortoisehg-5.6.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+DISTUTILS_USE_SETUPTOOLS=no
+
+inherit desktop distutils-r1 xdg-utils
+
+if [[ ${PV} != *9999* ]]; then
+	KEYWORDS="~amd64 ~arm64 ~x86"
+	SRC_URI="https://www.mercurial-scm.org/release/tortoisehg/targz/${P}.tar.gz"
+	HG_DEPEND=">=dev-vcs/mercurial-5.4
+		<dev-vcs/mercurial-5.7"
+else
+	inherit mercurial
+	EHG_REPO_URI="https://foss.heptapod.net/mercurial/tortoisehg/thg"
+	EHG_REVISION="stable"
+	HG_DEPEND=">=dev-vcs/mercurial-5.4"
+fi
+
+DESCRIPTION="Set of graphical tools for Mercurial"
+HOMEPAGE="https://tortoisehg.bitbucket.io/"
+
+LICENSE="GPL-2"
+SLOT="0"
+
+RDEPEND="
+	${HG_DEPEND}
+	dev-python/iniparse[${PYTHON_USEDEP}]
+	dev-python/pygments[${PYTHON_USEDEP}]
+	dev-python/PyQt5[network,svg,${PYTHON_USEDEP}]
+	>=dev-python/qscintilla-python-2.9.4[qt5(+),${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+
+distutils_enable_sphinx doc/source
+
+python_prepare_all() {
+	# Remove file that collides with >=mercurial-4.0 (bug #599266).
+	rm "${S}"/hgext3rd/__init__.py || die "can't remove /hgext3rd/__init__.py"
+	distutils-r1_python_prepare_all
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	dodoc doc/ReadMe*.txt doc/TODO contrib/mergetools.rc
+	newicon -s scalable icons/scalable/apps/thg.svg thg_logo.svg
+	domenu contrib/thg.desktop
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	elog "When startup of ${PN} fails with an API version mismatch error"
+	elog "between dev-python/sip and dev-python/PyQt5 please rebuild"
+	elog "dev-python/qscintilla-python."
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}