Browse Source

avidemux-2.7.8 from mv-overlay added

master
Kolan Sh 4 months ago
parent
commit
8eed06b838
  1. 1
      media-libs/avidemux-core/Manifest
  2. 98
      media-libs/avidemux-core/avidemux-core-2.7.8.ebuild
  3. 15
      media-libs/avidemux-core/metadata.xml
  4. 1
      media-libs/avidemux-plugins/Manifest
  5. 161
      media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild
  6. 20
      media-libs/avidemux-plugins/files/avidemux-plugins-2.6.20-optional-pulse.patch
  7. 23
      media-libs/avidemux-plugins/metadata.xml
  8. 2
      media-video/avidemux/Manifest
  9. 138
      media-video/avidemux/avidemux-2.7.8.ebuild
  10. 14
      media-video/avidemux/metadata.xml

1
media-libs/avidemux-core/Manifest

@ -0,0 +1 @@
DIST avidemux-2.7.8.tar.gz 22080267 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82

98
media-libs/avidemux-core/avidemux-core-2.7.8.ebuild

@ -0,0 +1,98 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_MAKEFILE_GENERATOR="emake"
inherit cmake flag-o-matic toolchain-funcs
DESCRIPTION="Core libraries for simple video cutting, filtering and encoding tasks"
HOMEPAGE="http://fixounet.free.fr/avidemux"
SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
# Multiple licenses because of all the bundled stuff.
LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
SLOT="2.7"
KEYWORDS="~amd64 ~x86"
IUSE="debug nls nvenc sdl system-ffmpeg vaapi vdpau xv"
# Trying to use virtual; ffmpeg misses aac,cpudetection USE flags now though, are they needed?
DEPEND="dev-db/sqlite:3
nvenc? ( media-video/nvidia_video_sdk )
sdl? ( media-libs/libsdl:0 )
system-ffmpeg? ( >=media-video/ffmpeg-9:0[mp3,theora] )
vaapi? ( x11-libs/libva:0= )
vdpau? ( x11-libs/libvdpau:0 )
xv? ( x11-libs/libXv:0 )
"
RDEPEND="${DEPEND}
!<media-libs/avidemux-core-${PV}
!<media-video/avidemux-${PV}
nls? ( virtual/libintl:0 )
"
BDEPEND="virtual/pkgconfig
nls? ( sys-devel/gettext )
!system-ffmpeg? ( dev-lang/yasm[nls=] )
"
S="${WORKDIR}/avidemux2-${PV}"
CMAKE_USE_DIR="${S}/${PN/-/_}"
src_prepare() {
cmake_src_prepare
if use system-ffmpeg ; then
# Preparations to support the system ffmpeg. Currently fails because
# it depends on files the system ffmpeg doesn't install.
local error="Failed to remove bundled ffmpeg."
rm -r cmake/admFFmpeg* cmake/ffmpeg* avidemux_core/ffmpeg_package \
buildCore/ffmpeg || die "${error}"
sed -e 's/include(admFFmpegUtil)//g' -e '/registerFFmpeg/d' \
-i avidemux/commonCmakeApplication.cmake || die "${error}"
sed -e 's/include(admFFmpegBuild)//g' \
-i avidemux_core/CMakeLists.txt || die "${error}"
else
local ffmpeg_args=(
--cc=$(tc-getCC)
--cxx=$(tc-getCXX)
--ar=$(tc-getAR)
--nm=$(tc-getNM)
--ranlib=$(tc-getRANLIB)
"--optflags='${CFLAGS}'"
)
sed -i \
-e "s/@@GENTOO_FFMPEG_FLAGS@@/${ffmpeg_args[*]}/" \
cmake/ffmpeg_configure.sh.cmake \
|| die
fi
}
src_configure() {
# See bug 432322.
use x86 && replace-flags -O0 -O1
local mycmakeargs=(
-DAVIDEMUX_SOURCE_DIR='${S}'
-DGETTEXT="$(usex nls)"
-DNVENC="$(usex nvenc)"
-DSDL="$(usex sdl)"
-DLIBVA="$(usex vaapi)"
-DVDPAU="$(usex vdpau)"
-DXVIDEO="$(usex xv)"
)
use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
cmake_src_configure
}
src_compile() {
cmake_src_compile
}
src_install() {
cmake_src_install
}

15
media-libs/avidemux-core/metadata.xml

@ -0,0 +1,15 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>media-video@gentoo.org</email>
<name>Gentoo Video project</name>
</maintainer>
<use>
<flag name="nvenc">Adds support for NVIDIA Encoder (NVENC) API for hardware accelerated encoding on NVIDIA cards.</flag>
<flag name="system-ffmpeg">Use the ffmpeg provided by the system.</flag>
</use>
<upstream>
<remote-id type="sourceforge">avidemux</remote-id>
</upstream>
</pkgmetadata>

1
media-libs/avidemux-plugins/Manifest

@ -0,0 +1 @@
DIST avidemux-2.7.8.tar.gz 22080267 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82

161
media-libs/avidemux-plugins/avidemux-plugins-2.7.8.ebuild

@ -0,0 +1,161 @@
# Copyright 1999-2021 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_MAKEFILE_GENERATOR="emake"
PYTHON_COMPAT=( python3_{7,8,9,10} )
inherit cmake flag-o-matic python-single-r1
DESCRIPTION="Plugins for the video editor media-video/avidemux"
HOMEPAGE="http://fixounet.free.fr/avidemux"
SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> avidemux-${PV}.tar.gz"
# Multiple licenses because of all the bundled stuff.
LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
SLOT="2.7"
IUSE="a52 aac aften alsa amr dcaenc debug dts fdk fontconfig fribidi jack lame libsamplerate cpu_flags_x86_mmx nvenc opengl opus oss pulseaudio qt5 truetype twolame vdpau vorbis vpx x264 x265 xv xvid"
KEYWORDS="~amd64 ~x86"
REQUIRED_USE="${PYTHON_REQUIRED_USE}"
COMMON_DEPEND="${PYTHON_DEPS}
~media-libs/avidemux-core-${PV}:${SLOT}[vdpau?]
~media-video/avidemux-${PV}:${SLOT}[opengl?,qt5?]
dev-lang/spidermonkey:0=
dev-libs/libxml2:2
media-libs/a52dec
media-libs/libass:0=
media-libs/libmad
media-libs/libmp4v2
media-libs/libpng:0=
virtual/libiconv
aac? (
media-libs/faac
media-libs/faad2
)
aften? ( media-libs/aften )
alsa? ( media-libs/alsa-lib )
amr? ( media-libs/opencore-amr )
dcaenc? ( media-sound/dcaenc )
dts? ( media-libs/libdca )
fdk? ( media-libs/fdk-aac:0= )
fontconfig? ( media-libs/fontconfig:1.0 )
fribidi? ( dev-libs/fribidi )
jack? (
virtual/jack
libsamplerate? ( media-libs/libsamplerate )
)
lame? ( media-sound/lame )
nvenc? ( amd64? ( media-video/nvidia_video_sdk ) )
opus? ( media-libs/opus )
pulseaudio? ( media-sound/pulseaudio )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtwidgets:5
)
truetype? ( media-libs/freetype:2 )
twolame? ( media-sound/twolame )
vorbis? ( media-libs/libvorbis )
vpx? ( media-libs/libvpx:0= )
x264? ( media-libs/x264:0= )
x265? ( media-libs/x265:0= )
xv? (
x11-libs/libX11
x11-libs/libXext
x11-libs/libXv
)
xvid? ( media-libs/xvid )
"
DEPEND="${COMMON_DEPEND}
oss? ( virtual/os-headers )
"
RDEPEND="${COMMON_DEPEND}
!<media-libs/avidemux-plugins-${PV}
"
S="${WORKDIR}/avidemux2-${PV}"
PATCHES=( "${FILESDIR}"/${PN}-2.6.20-optional-pulse.patch )
src_prepare() {
default
# Don't reapply PATCHES during cmake_src_prepare
unset PATCHES
processes="buildPluginsCommon:avidemux_plugins
buildPluginsCLI:avidemux_plugins"
use qt5 && processes+=" buildPluginsQt4:avidemux_plugins"
for process in ${processes} ; do
CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
done
}
src_configure() {
# See bug 432322.
use x86 && replace-flags -O0 -O1
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
local mycmakeargs=(
-DAVIDEMUX_SOURCE_DIR='${S}'
-DPLUGIN_UI=$(echo ${build/buildPlugins/} | tr '[:lower:]' '[:upper:]')
-DFAAC="$(usex aac)"
-DFAAD="$(usex aac)"
-DALSA="$(usex alsa)"
-DAFTEN="$(usex aften)"
-DDCAENC="$(usex dcaenc)"
-DFDK_AAC="$(usex fdk)"
-DOPENCORE_AMRWB="$(usex amr)"
-DOPENCORE_AMRNB="$(usex amr)"
-DLIBDCA="$(usex dts)"
-DFONTCONFIG="$(usex fontconfig)"
-DJACK="$(usex jack)"
-DLAME="$(usex lame)"
-DNVENC="$(usex nvenc)"
-DOPENGL="$(usex opengl)"
-DOPUS="$(usex opus)"
-DOSS="$(usex oss)"
-DPULSEAUDIOSIMPLE="$(usex pulseaudio)"
-DQT4=OFF
-DFREETYPE2="$(usex truetype)"
-DTWOLAME="$(usex twolame)"
-DX264="$(usex x264)"
-DX265="$(usex x265)"
-DXVIDEO="$(usex xv)"
-DXVID="$(usex xvid)"
-DVDPAU="$(usex vdpau)"
-DVORBIS="$(usex vorbis)"
-DLIBVORBIS="$(usex vorbis)"
-DVPXDEC="$(usex vpx)"
-DUSE_EXTERNAL_LIBA52=yes
-DUSE_EXTERNAL_LIBASS=yes
-DUSE_EXTERNAL_LIBMAD=yes
-DUSE_EXTERNAL_LIBMP4V2=yes
)
use qt5 && mycmakeargs+=( -DENABLE_QT5=True )
use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
done
}
src_compile() {
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
BUILD_DIR="${build}" cmake_src_compile
done
}
src_install() {
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
BUILD_DIR="${build}" cmake_src_install
done
}

20
media-libs/avidemux-plugins/files/avidemux-plugins-2.6.20-optional-pulse.patch

@ -0,0 +1,20 @@
--- a/cmake/admCheckAudioDeviceLibs.cmake
+++ b/cmake/admCheckAudioDeviceLibs.cmake
@@ -158,6 +158,7 @@
MESSAGE(STATUS "Checking for PULSEAUDIOSIMPLE")
MESSAGE(STATUS "*****************************")
+ IF (PULSEAUDIOSIMPLE)
IF (PULSEAUDIOSIMPLE_INCLUDE_DIR AND PULSEAUDIOSIMPLE_LIBRARIES)
# in cache already
SET(PULSEAUDIOSIMPLE_FIND_QUIETLY TRUE)
@@ -191,6 +192,9 @@
MARK_AS_ADVANCED(PULSEAUDIOSIMPLE_INCLUDE_DIR PULSEAUDIOSIMPLE_LIBRARIES)
APPEND_SUMMARY_LIST("Audio Device" "PulseAudio" "${USE_PULSE_SIMPLE}")
+ ELSE (PULSEAUDIOSIMPLE)
+ MESSAGE("${MSG_DISABLE_OPTION}")
+ ENDIF (PULSEAUDIOSIMPLE)
ELSE (UNIX AND NOT APPLE)
SET(PULSEAUDIOSIMPLE_CAPABLE FALSE)
ENDIF (UNIX AND NOT APPLE)

23
media-libs/avidemux-plugins/metadata.xml

@ -0,0 +1,23 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>media-video@gentoo.org</email>
<name>Gentoo Video project</name>
</maintainer>
<use>
<flag name="aften">Enable A/52 (AC-3) audio encoder support.</flag>
<flag name="amr">Enable Adaptive Multi-Rate format support via <pkg>media-libs/opencore-amr</pkg>.</flag>
<flag name="dcaenc">Enable DTS Coherent Acoustics audio encoder support via <pkg>media-sound/dcaenc</pkg>.</flag>
<flag name="fdk">Adds support for encoding AAC using <pkg>media-libs/fdk-aac</pkg>.</flag>
<flag name="fribidi">Enable unicode bidirectional algorithm support via <pkg>dev-libs/fribidi</pkg>.</flag>
<flag name="nvenc">Adds support for NVIDIA Encoder (NVENC) API for hardware accelerated encoding on NVIDIA cards.</flag>
<flag name="opus">Adds support for the Opus codec via <pkg>media-libs/opus</pkg>.</flag>
<flag name="twolame">Enable TwoLAME support via <pkg>media-sound/twolame</pkg>, an optimised MPEG Audio Layer 2 (MP2) encoder.</flag>
<flag name="vpx">Enable WebM VP8 Codec SDK support via <pkg>media-libs/libvpx</pkg>.</flag>
<flag name="x265">Enables HEVC support with <pkg>media-libs/x265</pkg>.</flag>
</use>
<upstream>
<remote-id type="sourceforge">avidemux</remote-id>
</upstream>
</pkgmetadata>

2
media-video/avidemux/Manifest

@ -0,0 +1,2 @@
DIST avidemux-2.7.8.tar.gz 22080267 SHA512 6cd5527ab34517a07bf73e46d01f15b7ff023ff34ed70ee54f1d7dbfb6cf57364a323b4ecb89bb9aadeb9bc05473aacb40d8c4eecc522840a3c1c4b3a8756d82
DIST avidemux-i18n-2.7.8.tar.gz 2488165 SHA512 a62b06a3d95577cf805be36f991ccb63d044b7c3633ada65bd5810f0e7d8eb41aa874ef5dd63de4fcacc0be073935bed827b2f0bceba77ab735ac8673c1ad39f

138
media-video/avidemux/avidemux-2.7.8.ebuild

@ -0,0 +1,138 @@
# Copyright 1999-2021 Gentoo Authors and Martin V\"ath
# Distributed under the terms of the GNU General Public License v2
EAPI=7
CMAKE_MAKEFILE_GENERATOR="emake"
inherit cmake desktop flag-o-matic qmake-utils xdg
DESCRIPTION="Video editor designed for simple cutting, filtering and encoding tasks"
HOMEPAGE="http://fixounet.free.fr/avidemux"
SRC_URI="https://github.com/mean00/avidemux2/archive/${PV}.tar.gz -> ${P}.tar.gz
https://github.com/mean00/avidemux2_i18n/archive/${PV}.tar.gz -> ${PN}-i18n-${PV}.tar.gz"
# Multiple licenses because of all the bundled stuff.
LICENSE="GPL-1 GPL-2 MIT PSF-2 public-domain"
SLOT="2.7"
KEYWORDS="~amd64 ~x86"
IUSE="debug nls nvenc opengl qt5 sdl vaapi vdpau xv"
BDEPEND="dev-lang/yasm
qt5? ( dev-qt/linguist-tools:5 )"
DEPEND="
~media-libs/avidemux-core-${PV}:${SLOT}[nls?,sdl?,vaapi?,vdpau?,xv?,nvenc?]
nvenc? ( amd64? ( media-video/nvidia_video_sdk:0 ) )
opengl? ( virtual/opengl:0 )
qt5? (
dev-qt/qtcore:5
dev-qt/qtgui:5
dev-qt/qtnetwork:5
dev-qt/qtopengl:5
dev-qt/qtwidgets:5
)
vaapi? ( x11-libs/libva:0= )
"
RDEPEND="${DEPEND}
nls? ( virtual/libintl:0 )
!<media-video/avidemux-${PV}
"
PDEPEND="~media-libs/avidemux-plugins-${PV}:${SLOT}[opengl?,qt5?]"
S="${WORKDIR}/avidemux2-${PV}"
src_unpack() {
default
mv -f -T avidemux2_i18n-${PV} "${S}"/avidemux/qt4/i18n >/dev/null || die
}
src_prepare() {
processes="buildCli:avidemux/cli"
use qt5 && processes+=" buildQt4:avidemux/qt4"
for process in ${processes} ; do
CMAKE_USE_DIR="${S}"/${process#*:} cmake_src_prepare
done
if use qt5; then
# Fix icon name -> avidemux-2.7
sed -i -e "/^Icon/ s:${PN}\.png:${PN}-${SLOT}:" appImage/${PN}.desktop || \
die "Icon name fix failed."
# The desktop file is broken. It uses avidemux3_portable instead of avidemux3_qt5
sed -i -re '/^Exec/ s:(avidemux3_)portable:\1qt5:' appImage/${PN}.desktop || \
die "Desktop file fix failed."
# QA warnings: missing trailing ';' and 'Application' is deprecated.
sed -i -e 's/Application;AudioVideo/AudioVideo;/g' appImage/${PN}.desktop || \
die "Desktop file fix failed."
# Now rename the desktop file to not collide with 2.6.
mv appImage/${PN}.desktop ${PN}-${SLOT}.desktop || die "Collision rename failed."
fi
# Remove "Build Option" dialog because it doesn't reflect
# what the GUI can or has been built with. (Bug #463628)
sed -i -e '/Build Option/d' avidemux/common/ADM_commonUI/myOwnMenu.h || \
die "Couldn't remove \"Build Option\" dialog."
# Fix underlinking with gold
sed -i -e 's/{QT_QTGUI_LIBRARY}/{QT_QTGUI_LIBRARY} -lXext/' \
avidemux/common/ADM_render/CMakeLists.txt || die
}
src_configure() {
# See bug 432322.
use x86 && replace-flags -O0 -O1
# The build relies on an avidemux-core header that uses 'nullptr'
# which is from >=C++11. Let's use the GCC-6 default C++ dialect.
append-cxxflags -std=c++14
local mycmakeargs=(
-DGETTEXT="$(usex nls)"
-DSDL="$(usex sdl)"
-DLibVA="$(usex vaapi)"
-DOPENGL="$(usex opengl)"
-DVDPAU="$(usex vdpau)"
-DXVIDEO="$(usex xv)"
)
use qt5 && mycmakeargs+=(
-DENABLE_QT5="$(usex qt5)"
-DLRELEASE_EXECUTABLE="$(qt5_get_bindir)/lrelease"
)
use debug && mycmakeargs+=( -DVERBOSE=1 -DADM_DEBUG=1 )
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
CMAKE_USE_DIR="${S}"/${process#*:} BUILD_DIR="${build}" cmake_src_configure
done
}
src_compile() {
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
BUILD_DIR="${build}" cmake_src_compile
done
}
src_test() {
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
BUILD_DIR="${build}" cmake_src_test
done
}
src_install() {
for process in ${processes} ; do
local build="${WORKDIR}/${P}_build/${process%%:*}"
BUILD_DIR="${build}" cmake_src_install
done
if use qt5; then
cd "${S}" || die "Can't enter source folder"
newicon ${PN}_icon.png ${PN}-${SLOT}.png
domenu ${PN}-${SLOT}.desktop
fi
}

14
media-video/avidemux/metadata.xml

@ -0,0 +1,14 @@
<?xml version="1.0" encoding="UTF-8"?>
<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
<pkgmetadata>
<maintainer type="project">
<email>media-video@gentoo.org</email>
<name>Gentoo Video project</name>
</maintainer>
<use>
<flag name="nvenc">Adds support for NVIDIA Encoder (NVENC) API for hardware accelerated encoding on NVIDIA cards.</flag>
</use>
<upstream>
<remote-id type="sourceforge">avidemux</remote-id>
</upstream>
</pkgmetadata>
Loading…
Cancel
Save