mpv-0.3.1 added
This commit is contained in:
Kolan Sh
parent
e05658e0d0
commit
63f29e5681
|
|
@ -0,0 +1,2 @@
|
|||
DIST mpv-0.3.1.tar.gz 2513567 SHA256 ddd365039faf0d26076633c118e854f4cf7b09e7de20f340e70bc24278fae4ae SHA512 55415fffdb4a6a9b0012f7c6efa2b665fbead12e1c511c6c4bd15bdba8ae0f5ee6b8183ef82cebb1cbb9e48dcd59d72913a7cfb3b408dc1db6fdc79dec0c20ab WHIRLPOOL 7fa3cb0bf375cac963009fb8840a51b6730b8e24005106cdfe6afa29ba637bd5728ed75c4991606a07e37bcbd57eb63b7ce62de5fd6e74286ee33263444f1268
|
||||
DIST waf-1.7.13 90702 SHA256 03cc750049350ee01cdbc584b70924e333fcc17ba4a2d04648dab1535538a873 SHA512 4388cd200d86d9757db95a138d75655e419fd9372de1dc392025b2ecfb9a0cc95d0b17639689ac293b753355af4baea0fc700ddd5d419755facc4e1dfa009521 WHIRLPOOL db94ba365aa84927942e1d95079f9efe377e646dcb7183d6a80d4b57ebbe195d48d23b7688216bd0b793e2f914e1d83caae3b517e385f891a26f670ebc17ed05
|
||||
|
|
@ -0,0 +1,236 @@
|
|||
# Copyright 1999-2014 Gentoo Foundation
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
# $Header: /var/cvsroot/gentoo-x86/media-video/mpv/mpv-0.3.1.ebuild,v 1.1 2014/01/03 15:07:58 zx2c4 Exp $
|
||||
|
||||
EAPI=5
|
||||
|
||||
EGIT_REPO_URI="https://github.com/mpv-player/mpv.git"
|
||||
|
||||
inherit base waf-utils pax-utils
|
||||
[[ ${PV} == *9999* ]] && inherit git-r3
|
||||
|
||||
DESCRIPTION="Video player based on MPlayer/mplayer2"
|
||||
HOMEPAGE="http://mpv.io/"
|
||||
SRC_URI="https://waf.googlecode.com/files/waf-1.7.13"
|
||||
[[ ${PV} == *9999* ]] || \
|
||||
SRC_URI+=" https://github.com/mpv-player/mpv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
[[ ${PV} == *9999* ]] || \
|
||||
KEYWORDS="~alpha ~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux"
|
||||
IUSE="+alsa bluray bs2b +cdio -doc-pdf dvb +dvd dvdnav +enca encode +iconv jack -joystick
|
||||
jpeg ladspa lcms +libass libcaca libguess lirc lua luajit +mpg123 -openal +opengl
|
||||
oss portaudio +postproc pulseaudio pvr +quvi -radio samba +shm v4l vaapi vcd vdpau
|
||||
vf-dlopen wayland +X xinerama +xscreensaver +xv"
|
||||
|
||||
REQUIRED_USE="
|
||||
dvdnav? ( dvd )
|
||||
enca? ( iconv )
|
||||
lcms? ( opengl )
|
||||
libguess? ( iconv )
|
||||
luajit? ( lua )
|
||||
opengl? ( || ( wayland X ) )
|
||||
pvr? ( v4l )
|
||||
radio? ( v4l || ( alsa oss ) )
|
||||
vaapi? ( X )
|
||||
vdpau? ( X )
|
||||
wayland? ( opengl )
|
||||
xinerama? ( X )
|
||||
xscreensaver? ( X )
|
||||
xv? ( X )
|
||||
"
|
||||
|
||||
RDEPEND+="
|
||||
|| (
|
||||
>=media-video/libav-9:=[encode?,threads,vaapi?,vdpau?]
|
||||
>=media-video/ffmpeg-1.2:0=[encode?,threads,vaapi?,vdpau?]
|
||||
)
|
||||
sys-libs/ncurses
|
||||
sys-libs/zlib
|
||||
X? (
|
||||
x11-libs/libXext
|
||||
x11-libs/libXxf86vm
|
||||
opengl? ( virtual/opengl )
|
||||
lcms? ( media-libs/lcms:2 )
|
||||
vaapi? ( >=x11-libs/libva-0.34.0[X(+)] )
|
||||
vdpau? ( >=x11-libs/libvdpau-0.2 )
|
||||
xinerama? ( x11-libs/libXinerama )
|
||||
xscreensaver? ( x11-libs/libXScrnSaver )
|
||||
xv? ( x11-libs/libXv )
|
||||
)
|
||||
alsa? ( media-libs/alsa-lib )
|
||||
bluray? ( >=media-libs/libbluray-0.2.1 )
|
||||
bs2b? ( media-libs/libbs2b )
|
||||
cdio? (
|
||||
|| (
|
||||
dev-libs/libcdio-paranoia
|
||||
<dev-libs/libcdio-0.90[-minimal]
|
||||
)
|
||||
)
|
||||
dvb? ( virtual/linuxtv-dvb-headers )
|
||||
dvd? (
|
||||
>=media-libs/libdvdread-4.1.3
|
||||
dvdnav? ( >=media-libs/libdvdnav-4.2.0 )
|
||||
)
|
||||
enca? ( app-i18n/enca )
|
||||
iconv? ( virtual/libiconv )
|
||||
jack? ( media-sound/jack-audio-connection-kit )
|
||||
jpeg? ( virtual/jpeg )
|
||||
ladspa? ( media-libs/ladspa-sdk )
|
||||
libass? (
|
||||
>=media-libs/libass-0.9.10[enca?,fontconfig]
|
||||
virtual/ttf-fonts
|
||||
)
|
||||
libcaca? ( >=media-libs/libcaca-0.99_beta18 )
|
||||
libguess? ( >=app-i18n/libguess-1.0 )
|
||||
lirc? ( app-misc/lirc )
|
||||
lua? (
|
||||
!luajit? ( >=dev-lang/lua-5.1 )
|
||||
luajit? ( dev-lang/luajit:2 )
|
||||
)
|
||||
mpg123? ( >=media-sound/mpg123-1.14.0 )
|
||||
openal? ( >=media-libs/openal-1.13 )
|
||||
portaudio? ( >=media-libs/portaudio-19_pre20111121 )
|
||||
postproc? (
|
||||
|| (
|
||||
media-libs/libpostproc
|
||||
>=media-video/ffmpeg-1.2:0[encode?,threads,vaapi?,vdpau?]
|
||||
)
|
||||
)
|
||||
pulseaudio? ( media-sound/pulseaudio )
|
||||
quvi? (
|
||||
>=media-libs/libquvi-0.4.1:=
|
||||
|| (
|
||||
>=media-video/libav-9[network]
|
||||
>=media-video/ffmpeg-1.2:0[network]
|
||||
)
|
||||
)
|
||||
samba? ( net-fs/samba )
|
||||
v4l? ( media-libs/libv4l )
|
||||
wayland? (
|
||||
>=dev-libs/wayland-1.2.0
|
||||
media-libs/mesa[egl,wayland]
|
||||
>=x11-libs/libxkbcommon-0.3.0
|
||||
)
|
||||
"
|
||||
ASM_DEP="dev-lang/yasm"
|
||||
DEPEND="${RDEPEND}
|
||||
virtual/pkgconfig
|
||||
>=dev-lang/perl-5.8
|
||||
dev-python/docutils
|
||||
doc-pdf? (
|
||||
dev-texlive/texlive-latex
|
||||
dev-texlive/texlive-latexrecommended
|
||||
dev-texlive/texlive-latexextra
|
||||
dev-tex/xcolor
|
||||
)
|
||||
X? (
|
||||
x11-proto/videoproto
|
||||
x11-proto/xf86vidmodeproto
|
||||
xinerama? ( x11-proto/xineramaproto )
|
||||
xscreensaver? ( x11-proto/scrnsaverproto )
|
||||
)
|
||||
amd64? ( ${ASM_DEP} )
|
||||
x86? ( ${ASM_DEP} )
|
||||
x86-fbsd? ( ${ASM_DEP} )
|
||||
"
|
||||
DOCS=( Copyright README.md etc/example.conf etc/input.conf )
|
||||
|
||||
pkg_setup() {
|
||||
if use !libass; then
|
||||
ewarn
|
||||
ewarn "You've disabled the libass flag. No OSD or subtitles will be displayed."
|
||||
fi
|
||||
|
||||
einfo "For additional format support you need to enable the support on your"
|
||||
einfo "libavcodec/libavformat provider:"
|
||||
einfo " media-video/libav or media-video/ffmpeg"
|
||||
}
|
||||
|
||||
src_unpack() {
|
||||
if [[ ${PV} == *9999* ]]; then
|
||||
git-r3_src_unpack
|
||||
else
|
||||
default_src_unpack
|
||||
fi
|
||||
|
||||
cp "${DISTDIR}"/waf-1.7.13 "${S}"/waf || die
|
||||
chmod 0755 "${S}"/waf || die
|
||||
}
|
||||
|
||||
src_prepare() {
|
||||
base_src_prepare
|
||||
}
|
||||
|
||||
src_configure() {
|
||||
# keep build reproducible
|
||||
# do not add -g to CFLAGS
|
||||
# SDL output is fallback for platforms where nothing better is available
|
||||
# media-sound/rsound is in pro-audio overlay only
|
||||
waf-utils_src_configure \
|
||||
--disable-build-date \
|
||||
--disable-debug-build \
|
||||
--disable-sdl \
|
||||
--disable-sdl2 \
|
||||
--disable-rsound \
|
||||
$(use_enable encode encoding) \
|
||||
$(use_enable joystick) \
|
||||
$(use_enable bluray libbluray) \
|
||||
$(use_enable vcd) \
|
||||
$(use_enable quvi libquvi) \
|
||||
$(use_enable samba libsmbclient) \
|
||||
$(use_enable lirc) \
|
||||
$(use_enable lua) \
|
||||
$(usex luajit '--lua=luajit' '') \
|
||||
$(use_enable doc-pdf pdf-build) \
|
||||
$(use_enable vf-dlopen vf-dlopen-filters) \
|
||||
$(use_enable cdio cdda) \
|
||||
$(use_enable dvd dvdread) \
|
||||
$(use_enable dvdnav) \
|
||||
$(use_enable enca) \
|
||||
$(use_enable iconv) \
|
||||
$(use_enable libass) \
|
||||
$(use_enable libguess) \
|
||||
$(use_enable dvb) \
|
||||
$(use_enable pvr) \
|
||||
$(use_enable v4l libv4l2) \
|
||||
$(use_enable v4l tv) \
|
||||
$(use_enable v4l tv-v4l2) \
|
||||
$(use_enable radio) \
|
||||
$(use_enable radio radio-capture) \
|
||||
$(use_enable radio radio-v4l2) \
|
||||
$(use_enable mpg123) \
|
||||
$(use_enable jpeg) \
|
||||
$(use_enable libcaca caca) \
|
||||
$(use_enable postproc libpostproc) \
|
||||
$(use_enable alsa) \
|
||||
$(use_enable jack) \
|
||||
$(use_enable ladspa) \
|
||||
$(use_enable portaudio) \
|
||||
$(use_enable bs2b libbs2b) \
|
||||
$(use_enable openal) \
|
||||
$(use_enable oss oss-audio) \
|
||||
$(use_enable pulseaudio pulse) \
|
||||
$(use_enable shm) \
|
||||
$(use_enable X x11) \
|
||||
$(use_enable vaapi) \
|
||||
$(use_enable vdpau) \
|
||||
$(use_enable wayland) \
|
||||
$(use_enable xinerama) \
|
||||
$(use_enable xv) \
|
||||
$(use_enable opengl gl) \
|
||||
$(use_enable lcms lcms2) \
|
||||
$(use_enable xscreensaver xss) \
|
||||
--confdir="${EPREFIX}"/etc/${PN} \
|
||||
--mandir="${EPREFIX}"/usr/share/man \
|
||||
--docdir="${EPREFIX}"/usr/share/doc/${PF}
|
||||
}
|
||||
|
||||
src_install() {
|
||||
waf-utils_src_install
|
||||
|
||||
if use luajit; then
|
||||
pax-mark -m "${ED}"usr/bin/mpv
|
||||
fi
|
||||
}
|
||||
Loading…
Reference in New Issue