GtkDatabox 0.9.3.0 added.

x11-libs/gtkdatabox/Manifest

@@ -0,0 +1 @@
+DIST gtkdatabox-0.9.3.0.tar.gz 2883977 SHA256 1f426b525c31a9ba8bf2b61084b7aef89eaed11f8d0b2a54bde467da16692ff2 SHA512 5c2464dafcf9cdd4ee11bec6f8e627533c0270fe28d736e1be45ad084c42d430a50c39cf08531138627cc59ab034a191ecd7b97ccfce633467ff99e6e9cd593a WHIRLPOOL ccd9b2b10c698868a1f6b2520a4ee90450450acc44ed7b38161baa5313378a406193e6cdabf5d7845b8727ca59f9ce142f3ee05bdcb6433f01835a079eecf8f4

x11-libs/gtkdatabox/gtkdatabox-0.9.3.0.ebuild

@@ -0,0 +1,58 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="4"
+inherit eutils
+
+DESCRIPTION="Gtk+ Widgets for live display of large amounts of fluctuating numerical data"
+HOMEPAGE="https://sourceforge.net/projects/gtkdatabox/"
+SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="amd64 x86"
+IUSE="doc examples +glade static-libs test"
+
+RDEPEND="
+	glade? (
+		gnome-base/libglade
+	)
+	x11-libs/cairo
+	x11-libs/gtk+:3
+	x11-libs/pango
+"
+DEPEND=${RDEPEND}
+
+src_prepare() {
+	# Remove -D.*DISABLE_DEPRECATED cflags
+	find . -iname 'Makefile.am' -exec \
+		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 1 failed"
+	# Do Makefile.in after Makefile.am to avoid automake maintainer-mode
+	find . -iname 'Makefile.in' -exec \
+		sed -e '/-D[A-Z_]*DISABLE_DEPRECATED/d' -i {} + || die "sed 2 failed"
+	sed -e '/SUBDIRS/{s: examples::;}' -i Makefile.am -i Makefile.in || die
+}
+
+src_configure() {
+	econf \
+		$(use_enable doc gtk-doc) \
+		$(use_enable glade libglade) \
+		$(use_enable glade) \
+		$(use_enable static-libs static) \
+		$(use_enable test gtktest) \
+		--disable-dependency-tracking \
+		--enable-libtool-lock
+}
+
+src_install() {
+	default
+
+	prune_libtool_files
+
+	dodoc AUTHORS ChangeLog README TODO
+	if use examples; then
+		docinto examples
+		dodoc "${S}"/examples/*
+	fi
+}