a7ef02253b
This is an extensive refactoring of the Cray compiler wrapper usage. Using the new compiler wrapper checks, the CrayPrgEnv info files have been moved from Platform/ to Compiler/. The adjusted naming convention allows the compiler-wrapper information files to be loaded for both the CrayLinuxEnvironment platform when cross-compiling and the Linux platform if building natively on the Cray compute nodes. It also creates a separation of common arguments for compiler id and language information used to perform the appropriate introspection of implicit arguments and libraries used by the compiler wrappers based on the loaded module environment.
84 lines
3.2 KiB
CMake
84 lines
3.2 KiB
CMake
# Guard against multiple inclusions
|
|
if(__craylinux_crayprgenv)
|
|
return()
|
|
endif()
|
|
set(__craylinux_crayprgenv 1)
|
|
|
|
macro(__cray_extract_args cmd tag_regex out_var)
|
|
string(REGEX MATCHALL "${tag_regex}" args "${cmd}")
|
|
foreach(arg IN LISTS args)
|
|
string(REGEX REPLACE "^${tag_regex}$" "\\2" param "${arg}")
|
|
get_filename_component(param_abs "${param}" ABSOLUTE)
|
|
list(APPEND ${out_var} ${param_abs})
|
|
endforeach()
|
|
endmacro()
|
|
|
|
function(__cray_extract_implicit src compiler_cmd link_cmd lang include_dirs_var link_dirs_var link_libs_var)
|
|
execute_process(
|
|
COMMAND ${CMAKE_${lang}_COMPILER}
|
|
${CMAKE_${lang}_VERBOSE_FLAG} -o cray_extract_implicit_${lang} ${src}
|
|
RESULT_VARIABLE result
|
|
OUTPUT_VARIABLE output
|
|
ERROR_VARIABLE error
|
|
)
|
|
string(REGEX REPLACE "\r?\n" ";" output_lines "${output}\n${error}")
|
|
foreach(line IN LISTS output_lines)
|
|
if("${line}" MATCHES "${compiler_cmd}")
|
|
__cray_extract_args("${line}" " -(I ?|isystem )([^ ]*)" include_dirs)
|
|
set(processed_include 1)
|
|
endif()
|
|
if("${line}" MATCHES "${link_cmd}")
|
|
__cray_extract_args("${line}" " -(L ?)([^ ]*)" link_dirs)
|
|
__cray_extract_args("${line}" " -(l ?)([^ ]*)" link_libs)
|
|
set(processed_link 1)
|
|
endif()
|
|
if(processed_include AND processed_link)
|
|
break()
|
|
endif()
|
|
endforeach()
|
|
|
|
set(${include_dirs_var} "${include_dirs}" PARENT_SCOPE)
|
|
set(${link_dirs_var} "${link_dirs}" PARENT_SCOPE)
|
|
set(${link_libs_var} "${link_libs}" PARENT_SCOPE)
|
|
set(CRAY_${lang}_EXTRACTED_IMPLICIT 1 CACHE INTERNAL "" FORCE)
|
|
endfunction()
|
|
|
|
macro(__CrayPrgEnv_setup lang test_src compiler_cmd link_cmd)
|
|
if(DEFINED ENV{CRAYPE_VERSION})
|
|
message(STATUS "Cray Programming Environment $ENV{CRAYPE_VERSION} ${lang}")
|
|
elseif(DEFINED ENV{ASYNCPE_VERSION})
|
|
message(STATUS "Cray XT Programming Environment $ENV{ASYNCPE_VERSION} ${lang}")
|
|
endif()
|
|
|
|
# Flags for the Cray wrappers
|
|
set(CMAKE_STATIC_LIBRARY_LINK_${lang}_FLAGS "-static")
|
|
set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "")
|
|
set(CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS "-shared")
|
|
set(CMAKE_SHARED_LIBRARY_LINK_${lang}_FLAGS "-dynamic")
|
|
|
|
# If the link type is not explicitly specified in the environment then
|
|
# the Cray wrappers assume that the code will be built staticly so
|
|
# we check the following condition(s) are NOT met
|
|
# Compiler flags are explicitly dynamic
|
|
# Env var is dynamic and compiler flags are not explicitly static
|
|
if(NOT (((CMAKE_${lang}_FLAGS MATCHES "(^| )-dynamic($| )") OR
|
|
(CMAKE_EXE_LINKER_FLAGS MATCHES "(^| )-dynamic($| )"))
|
|
OR
|
|
(("$ENV{CRAYPE_LINK_TYPE}" STREQUAL "dynamic") AND
|
|
NOT ((CMAKE_${lang}_FLAGS MATCHES "(^| )-static($| )") OR
|
|
(CMAKE_EXE_LINKER_FLAGS MATCHES "(^| )-static($| )")))))
|
|
set_property(GLOBAL PROPERTY TARGET_SUPPORTS_SHARED_LIBS FALSE)
|
|
set(BUILD_SHARED_LIBS FALSE CACHE BOOL "")
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES ".a")
|
|
set(CMAKE_LINK_SEARCH_START_STATIC TRUE)
|
|
endif()
|
|
if(NOT CRAY_${lang}_EXTRACTED_IMPLICIT)
|
|
__cray_extract_implicit(
|
|
${test_src} ${compiler_cmd} ${link_cmd} ${lang}
|
|
CMAKE_${lang}_IMPLICIT_INCLUDE_DIRECTORIES
|
|
CMAKE_${lang}_IMPLICIT_LINK_DIRECTORIES
|
|
CMAKE_${lang}_IMPLICIT_LINK_LIBRARIES
|
|
)
|
|
endif()
|
|
endmacro()
|