86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
82 lines
2.7 KiB
CMake
82 lines
2.7 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
#-----------------------------------------------------------------------------
|
|
# set some special flags for different compilers
|
|
#
|
|
if(CMAKE_GENERATOR MATCHES "Visual Studio 7")
|
|
set(CMAKE_SKIP_COMPATIBILITY_TESTS 1)
|
|
endif()
|
|
|
|
if(WIN32 AND CMAKE_C_COMPILER_ID STREQUAL "Intel")
|
|
set(_INTEL_WINDOWS 1)
|
|
endif()
|
|
|
|
# Disable deprecation warnings for standard C functions.
|
|
# really only needed for newer versions of VS, but should
|
|
# not hurt other versions, and this will work into the
|
|
# future
|
|
if(MSVC OR _INTEL_WINDOWS)
|
|
add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE)
|
|
else()
|
|
endif()
|
|
|
|
#silence duplicate symbol warnings on AIX
|
|
if(CMAKE_SYSTEM_NAME MATCHES "AIX")
|
|
if(NOT CMAKE_COMPILER_IS_GNUCXX)
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -bhalt:5 ")
|
|
endif()
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "IRIX")
|
|
if(NOT CMAKE_COMPILER_IS_GNUCXX)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wl,-woff84 -no_auto_include")
|
|
set(CMAKE_EXE_LINKER_FLAGS "${CMAKE_EXE_LINKER_FLAGS} -Wl,-woff15")
|
|
endif()
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM MATCHES "OSF1-V")
|
|
if(NOT CMAKE_COMPILER_IS_GNUCXX)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -timplicit_local -no_implicit_include ")
|
|
endif()
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_NAME MATCHES "HP-UX" AND CMAKE_CXX_COMPILER_ID MATCHES "HP")
|
|
# HP aCC since version 3.80 supports the flag +hpxstd98 to get ANSI C++98
|
|
# template support. It is known that version 6.25 doesn't need that flag.
|
|
# Versions prior to 3.80 will not be able to build CMake. Current assumption:
|
|
# it is needed for every version from 3.80 to 4 to get it working.
|
|
if(CMAKE_CXX_COMPILER_VERSION VERSION_LESS 4 AND
|
|
NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 3.80)
|
|
# use new C++ library and improved template support
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -AA +hpxstd98")
|
|
endif()
|
|
endif()
|
|
|
|
# Workaround for short jump tables on PA-RISC
|
|
if(CMAKE_SYSTEM_PROCESSOR MATCHES "^parisc")
|
|
if(CMAKE_COMPILER_IS_GNUCC)
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} -mlong-calls")
|
|
endif()
|
|
if(CMAKE_COMPILER_IS_GNUCXX)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -mlong-calls")
|
|
endif()
|
|
endif()
|
|
|
|
if (CMAKE_CXX_COMPILER_ID STREQUAL SunPro)
|
|
if (NOT CMAKE_CXX_COMPILER_VERSION VERSION_LESS 5.13)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++03")
|
|
else()
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -library=stlport4")
|
|
endif()
|
|
endif()
|
|
|
|
# use the ansi CXX compile flag for building cmake
|
|
if (CMAKE_ANSI_CXXFLAGS)
|
|
set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_ANSI_CXXFLAGS}")
|
|
endif ()
|
|
|
|
if (CMAKE_ANSI_CFLAGS)
|
|
set(CMAKE_C_FLAGS "${CMAKE_C_FLAGS} ${CMAKE_ANSI_CFLAGS}")
|
|
endif ()
|