afb00fef19
Teach the Windows-GNU.cmake platform file to look for Visual Studio tools matching the target ABI. Add an extra step to the link command for shared libraries and executables that export symbols and on which a new GNUtoMS property is set (initialized by the CMAKE_GNUtoMS option). Tell the GNU linker to output a module definition (.def) file listing exported symbols in addition to the GNU-format import library (.dll.a). Pass the .def file to the MS "lib" tool to construct a MS-format DLL import library (.lib). Teach the install(TARGETS) command to install the MS import library next to the GNU one. Teach the install(EXPORT) and export() command to set the IMPORTED_IMPLIB property pointing at the import library to use the import library matching the tools in the importing project.
182 lines
8.3 KiB
CMake
182 lines
8.3 KiB
CMake
|
|
#=============================================================================
|
|
# Copyright 2002-2009 Kitware, Inc.
|
|
#
|
|
# Distributed under the OSI-approved BSD License (the "License");
|
|
# see accompanying file Copyright.txt for details.
|
|
#
|
|
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
|
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
|
# See the License for more information.
|
|
#=============================================================================
|
|
# (To distribute this file outside of CMake, substitute the full
|
|
# License text for the above reference.)
|
|
|
|
# This module is shared by multiple languages; use include blocker.
|
|
if(__WINDOWS_GNU)
|
|
return()
|
|
endif()
|
|
set(__WINDOWS_GNU 1)
|
|
|
|
set(CMAKE_IMPORT_LIBRARY_PREFIX "lib")
|
|
set(CMAKE_SHARED_LIBRARY_PREFIX "lib")
|
|
set(CMAKE_SHARED_MODULE_PREFIX "lib")
|
|
set(CMAKE_STATIC_LIBRARY_PREFIX "lib")
|
|
|
|
set(CMAKE_EXECUTABLE_SUFFIX ".exe")
|
|
set(CMAKE_IMPORT_LIBRARY_SUFFIX ".dll.a")
|
|
set(CMAKE_SHARED_LIBRARY_SUFFIX ".dll")
|
|
set(CMAKE_SHARED_MODULE_SUFFIX ".dll")
|
|
set(CMAKE_STATIC_LIBRARY_SUFFIX ".a")
|
|
|
|
if(MSYS OR MINGW)
|
|
set(CMAKE_EXTRA_LINK_EXTENSIONS ".lib") # MinGW can also link to a MS .lib
|
|
endif()
|
|
|
|
if(MINGW)
|
|
set(CMAKE_FIND_LIBRARY_PREFIXES "lib" "")
|
|
set(CMAKE_FIND_LIBRARY_SUFFIXES ".dll" ".dll.a" ".a" ".lib")
|
|
set(CMAKE_C_STANDARD_LIBRARIES_INIT "-lkernel32 -luser32 -lgdi32 -lwinspool -lshell32 -lole32 -loleaut32 -luuid -lcomdlg32 -ladvapi32")
|
|
set(CMAKE_CXX_STANDARD_LIBRARIES_INIT "${CMAKE_C_STANDARD_LIBRARIES_INIT}")
|
|
endif()
|
|
|
|
set(CMAKE_DL_LIBS "")
|
|
set(CMAKE_LIBRARY_PATH_FLAG "-L")
|
|
set(CMAKE_LINK_LIBRARY_FLAG "-l")
|
|
set(CMAKE_LINK_DEF_FILE_FLAG "") # Empty string: passing the file is enough
|
|
set(CMAKE_LINK_LIBRARY_SUFFIX "")
|
|
set(CMAKE_CREATE_WIN32_EXE "-mwindows")
|
|
|
|
set(CMAKE_GNULD_IMAGE_VERSION
|
|
"-Wl,--major-image-version,<TARGET_VERSION_MAJOR>,--minor-image-version,<TARGET_VERSION_MINOR>")
|
|
|
|
# Check if GNU ld is too old to support @FILE syntax.
|
|
set(__WINDOWS_GNU_LD_RESPONSE 1)
|
|
execute_process(COMMAND ld -v OUTPUT_VARIABLE _help ERROR_VARIABLE _help)
|
|
if("${_help}" MATCHES "GNU ld .* 2\\.1[1-6]")
|
|
set(__WINDOWS_GNU_LD_RESPONSE 0)
|
|
endif()
|
|
|
|
enable_language(RC)
|
|
|
|
macro(__windows_compiler_gnu lang)
|
|
|
|
if(MSYS OR MINGW)
|
|
# Create archiving rules to support large object file lists for static libraries.
|
|
set(CMAKE_${lang}_ARCHIVE_CREATE "<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS>")
|
|
set(CMAKE_${lang}_ARCHIVE_APPEND "<CMAKE_AR> r <TARGET> <LINK_FLAGS> <OBJECTS>")
|
|
set(CMAKE_${lang}_ARCHIVE_FINISH "<CMAKE_RANLIB> <TARGET>")
|
|
|
|
# Initialize C link type selection flags. These flags are used when
|
|
# building a shared library, shared module, or executable that links
|
|
# to other libraries to select whether to use the static or shared
|
|
# versions of the libraries.
|
|
foreach(type SHARED_LIBRARY SHARED_MODULE EXE)
|
|
set(CMAKE_${type}_LINK_STATIC_${lang}_FLAGS "-Wl,-Bstatic")
|
|
set(CMAKE_${type}_LINK_DYNAMIC_${lang}_FLAGS "-Wl,-Bdynamic")
|
|
endforeach(type)
|
|
endif()
|
|
|
|
set(CMAKE_SHARED_LIBRARY_${lang}_FLAGS "") # No -fPIC on Windows
|
|
set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_OBJECTS ${__WINDOWS_GNU_LD_RESPONSE})
|
|
set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_INCLUDES 1)
|
|
|
|
# We prefer "@" for response files but it is not supported by gcc 3.
|
|
execute_process(COMMAND ${CMAKE_${lang}_COMPILER} --version OUTPUT_VARIABLE _ver ERROR_VARIABLE _ver)
|
|
if("${_ver}" MATCHES "\\(GCC\\) 3\\.")
|
|
if("${lang}" STREQUAL "Fortran")
|
|
# The GNU Fortran compiler reports an error:
|
|
# no input files; unwilling to write output files
|
|
# when the response file is passed with "-Wl,@".
|
|
set(CMAKE_Fortran_USE_RESPONSE_FILE_FOR_OBJECTS 0)
|
|
else()
|
|
# Use "-Wl,@" to pass the response file to the linker.
|
|
set(CMAKE_${lang}_RESPONSE_FILE_LINK_FLAG "-Wl,@")
|
|
endif()
|
|
# The GNU 3.x compilers do not support response files (only linkers).
|
|
set(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_INCLUDES 0)
|
|
elseif(CMAKE_${lang}_USE_RESPONSE_FILE_FOR_OBJECTS)
|
|
# Use "@" to pass the response file to the front-end.
|
|
set(CMAKE_${lang}_RESPONSE_FILE_LINK_FLAG "@")
|
|
endif()
|
|
|
|
# Binary link rules.
|
|
set(CMAKE_${lang}_CREATE_SHARED_MODULE
|
|
"<CMAKE_${lang}_COMPILER> <CMAKE_SHARED_MODULE_${lang}_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_MODULE_CREATE_${lang}_FLAGS> -o <TARGET> ${CMAKE_GNULD_IMAGE_VERSION} <OBJECTS> <LINK_LIBRARIES>")
|
|
set(CMAKE_${lang}_CREATE_SHARED_LIBRARY
|
|
"<CMAKE_${lang}_COMPILER> <CMAKE_SHARED_LIBRARY_${lang}_FLAGS> <LINK_FLAGS> <CMAKE_SHARED_LIBRARY_CREATE_${lang}_FLAGS> -o <TARGET> -Wl,--out-implib,<TARGET_IMPLIB> ${CMAKE_GNULD_IMAGE_VERSION} <OBJECTS> <LINK_LIBRARIES>")
|
|
set(CMAKE_${lang}_LINK_EXECUTABLE
|
|
"<CMAKE_${lang}_COMPILER> <FLAGS> <CMAKE_${lang}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> -Wl,--out-implib,<TARGET_IMPLIB> ${CMAKE_GNULD_IMAGE_VERSION} <LINK_LIBRARIES>")
|
|
|
|
list(APPEND CMAKE_${lang}_ABI_FILES "Platform/Windows-GNU-${lang}-ABI")
|
|
|
|
# Support very long lists of object files.
|
|
if("${CMAKE_${lang}_RESPONSE_FILE_LINK_FLAG}" STREQUAL "@")
|
|
foreach(rule CREATE_SHARED_MODULE CREATE_SHARED_LIBRARY LINK_EXECUTABLE)
|
|
# The gcc/collect2/ld toolchain does not use response files
|
|
# internally so we cannot pass long object lists. Instead pass
|
|
# the object file list in a response file to the archiver to put
|
|
# them in a temporary archive. Hand the archive to the linker.
|
|
string(REPLACE "<OBJECTS>" "-Wl,--whole-archive <OBJECT_DIR>/objects.a -Wl,--no-whole-archive"
|
|
CMAKE_${lang}_${rule} "${CMAKE_${lang}_${rule}}")
|
|
set(CMAKE_${lang}_${rule}
|
|
"<CMAKE_COMMAND> -E remove -f <OBJECT_DIR>/objects.a"
|
|
"<CMAKE_AR> cr <OBJECT_DIR>/objects.a <OBJECTS>"
|
|
"${CMAKE_${lang}_${rule}}"
|
|
)
|
|
endforeach()
|
|
endif()
|
|
endmacro()
|
|
|
|
macro(__windows_compiler_gnu_abi lang)
|
|
if(CMAKE_NO_GNUtoMS)
|
|
set(CMAKE_GNUtoMS 0)
|
|
else()
|
|
option(CMAKE_GNUtoMS "Convert GNU import libraries to MS format (requires Visual Studio)" OFF)
|
|
endif()
|
|
|
|
if(CMAKE_GNUtoMS AND NOT CMAKE_GNUtoMS_LIB)
|
|
# Find MS development environment setup script for this architecture.
|
|
if("${CMAKE_SIZEOF_VOID_P}" EQUAL 4)
|
|
find_program(CMAKE_GNUtoMS_VCVARS NAMES vcvars32.bat
|
|
DOC "Visual Studio vcvars32.bat"
|
|
PATHS
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\11.0\\Setup\\VC;ProductDir]/bin"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\10.0\\Setup\\VC;ProductDir]/bin"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\9.0\\Setup\\VC;ProductDir]/bin"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\8.0\\Setup\\VC;ProductDir]/bin"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\7.1\\Setup\\VC;ProductDir]/bin"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\6.0\\Setup\\Microsoft Visual C++;ProductDir]/bin"
|
|
)
|
|
set(CMAKE_GNUtoMS_ARCH x86)
|
|
elseif("${CMAKE_SIZEOF_VOID_P}" EQUAL 8)
|
|
find_program(CMAKE_GNUtoMS_VCVARS NAMES vcvarsamd64.bat
|
|
DOC "Visual Studio vcvarsamd64.bat"
|
|
PATHS
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\11.0\\Setup\\VC;ProductDir]/bin/amd64"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\10.0\\Setup\\VC;ProductDir]/bin/amd64"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\9.0\\Setup\\VC;ProductDir]/bin/amd64"
|
|
"[HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\VisualStudio\\8.0\\Setup\\VC;ProductDir]/bin/amd64"
|
|
)
|
|
set(CMAKE_GNUtoMS_ARCH amd64)
|
|
endif()
|
|
set_property(CACHE CMAKE_GNUtoMS_VCVARS PROPERTY ADVANCED 1)
|
|
if(CMAKE_GNUtoMS_VCVARS)
|
|
# Create helper script to run lib.exe from MS environment.
|
|
string(REPLACE "/" "\\" CMAKE_GNUtoMS_BAT "${CMAKE_GNUtoMS_VCVARS}")
|
|
set(CMAKE_GNUtoMS_LIB ${CMAKE_BINARY_DIR}/CMakeFiles/CMakeGNUtoMS_lib.bat)
|
|
configure_file(${CMAKE_ROOT}/Modules/Platform/GNUtoMS_lib.bat.in ${CMAKE_GNUtoMS_LIB})
|
|
else()
|
|
message(WARNING "Disabling CMAKE_GNUtoMS option because CMAKE_GNUtoMS_VCVARS is not set.")
|
|
set(CMAKE_GNUtoMS 0)
|
|
endif()
|
|
endif()
|
|
|
|
if(CMAKE_GNUtoMS)
|
|
# Teach CMake how to create a MS import library at link time.
|
|
set(CMAKE_${lang}_GNUtoMS_RULE " -Wl,--output-def,<TARGET_NAME>.def"
|
|
"<CMAKE_COMMAND> -Dlib=\"${CMAKE_GNUtoMS_LIB}\" -Ddef=\"<TARGET_NAME>.def\" -Ddll=\"<TARGET>\" -Dimp=\"<TARGET_IMPLIB>\" -P \"${CMAKE_ROOT}/Modules/Platform/GNUtoMS_lib.cmake\""
|
|
)
|
|
endif()
|
|
endmacro()
|