86578eccf2
Per-source copyright/license notice headers that spell out copyright holder names and years are hard to maintain and often out-of-date or plain wrong. Precise contributor information is already maintained automatically by the version control tool. Ultimately it is the receiver of a file who is responsible for determining its licensing status, and per-source notices are merely a convenience. Therefore it is simpler and more accurate for each source to have a generic notice of the license name and references to more detailed information on copyright holders and full license terms. Our `Copyright.txt` file now contains a list of Contributors whose names appeared source-level copyright notices. It also references version control history for more precise information. Therefore we no longer need to spell out the list of Contributors in each source file notice. Replace CMake per-source copyright/license notice headers with a short description of the license and links to `Copyright.txt` and online information available from "https://cmake.org/licensing". The online URL also handles cases of modules being copied out of our source into other projects, so we can drop our notices about replacing links with full license text. Run the `Utilities/Scripts/filter-notices.bash` script to perform the majority of the replacements mechanically. Manually fix up shebang lines and trailing newlines in a few files. Manually update the notices in a few files that the script does not handle.
140 lines
5.6 KiB
CMake
140 lines
5.6 KiB
CMake
# Distributed under the OSI-approved BSD 3-Clause License. See accompanying
|
|
# file Copyright.txt or https://cmake.org/licensing for details.
|
|
|
|
|
|
if(UNIX)
|
|
set(CMAKE_ASM${ASM_DIALECT}_OUTPUT_EXTENSION .o)
|
|
else()
|
|
set(CMAKE_ASM${ASM_DIALECT}_OUTPUT_EXTENSION .obj)
|
|
endif()
|
|
|
|
set(CMAKE_INCLUDE_FLAG_ASM${ASM_DIALECT} "-I") # -I
|
|
set(CMAKE_BASE_NAME)
|
|
get_filename_component(CMAKE_BASE_NAME "${CMAKE_ASM${ASM_DIALECT}_COMPILER}" NAME_WE)
|
|
|
|
if("${CMAKE_BASE_NAME}" STREQUAL "as")
|
|
set(CMAKE_BASE_NAME gas)
|
|
endif()
|
|
|
|
# Load compiler-specific information.
|
|
set(_INCLUDED_FILE "")
|
|
if(CMAKE_ASM${ASM_DIALECT}_COMPILER_ID)
|
|
include(Compiler/${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
|
|
endif()
|
|
if(NOT _INCLUDED_FILE)
|
|
if("ASM${ASM_DIALECT}" STREQUAL "ASM")
|
|
message(STATUS "Warning: Did not find file Compiler/${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT}")
|
|
endif()
|
|
include(Platform/${CMAKE_BASE_NAME} OPTIONAL)
|
|
endif()
|
|
|
|
if(CMAKE_SYSTEM_PROCESSOR)
|
|
include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
|
|
if(NOT _INCLUDED_FILE)
|
|
include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME}-${CMAKE_SYSTEM_PROCESSOR} OPTIONAL)
|
|
endif()
|
|
endif()
|
|
|
|
include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_ASM${ASM_DIALECT}_COMPILER_ID}-ASM${ASM_DIALECT} OPTIONAL RESULT_VARIABLE _INCLUDED_FILE)
|
|
if(NOT _INCLUDED_FILE)
|
|
include(Platform/${CMAKE_SYSTEM_NAME}-${CMAKE_BASE_NAME} OPTIONAL)
|
|
endif()
|
|
|
|
# This should be included before the _INIT variables are
|
|
# used to initialize the cache. Since the rule variables
|
|
# have if blocks on them, users can still define them here.
|
|
# But, it should still be after the platform file so changes can
|
|
# be made to those values.
|
|
|
|
if(CMAKE_USER_MAKE_RULES_OVERRIDE)
|
|
# Save the full path of the file so try_compile can use it.
|
|
include(${CMAKE_USER_MAKE_RULES_OVERRIDE} RESULT_VARIABLE _override)
|
|
set(CMAKE_USER_MAKE_RULES_OVERRIDE "${_override}")
|
|
endif()
|
|
|
|
if(CMAKE_USER_MAKE_RULES_OVERRIDE_ASM)
|
|
# Save the full path of the file so try_compile can use it.
|
|
include(${CMAKE_USER_MAKE_RULES_OVERRIDE_ASM} RESULT_VARIABLE _override)
|
|
set(CMAKE_USER_MAKE_RULES_OVERRIDE_ASM "${_override}")
|
|
endif()
|
|
|
|
# Set default assembler file extensions:
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_SOURCE_FILE_EXTENSIONS)
|
|
set(CMAKE_ASM${ASM_DIALECT}_SOURCE_FILE_EXTENSIONS s;S;asm)
|
|
endif()
|
|
|
|
|
|
# Support for CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT and friends:
|
|
set(CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT "$ENV{ASM${ASM_DIALECT}FLAGS} ${CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT}")
|
|
|
|
foreach(c "" _DEBUG _RELEASE _MINSIZEREL _RELWITHDEBINFO)
|
|
string(STRIP "${CMAKE_ASM${ASM_DIALECT}_FLAGS${c}_INIT}" CMAKE_ASM${ASM_DIALECT}_FLAGS${c}_INIT)
|
|
endforeach()
|
|
|
|
set (CMAKE_ASM${ASM_DIALECT}_FLAGS "${CMAKE_ASM${ASM_DIALECT}_FLAGS_INIT}" CACHE STRING
|
|
"Flags used by the assembler during all build types.")
|
|
|
|
if(NOT CMAKE_NOT_USING_CONFIG_FLAGS)
|
|
# default build type is none
|
|
if(NOT CMAKE_NO_BUILD_TYPE)
|
|
set (CMAKE_BUILD_TYPE ${CMAKE_BUILD_TYPE_INIT} CACHE STRING
|
|
"Choose the type of build, options are: None, Debug Release RelWithDebInfo MinSizeRel.")
|
|
endif()
|
|
set (CMAKE_ASM${ASM_DIALECT}_FLAGS_DEBUG "${CMAKE_ASM${ASM_DIALECT}_FLAGS_DEBUG_INIT}" CACHE STRING
|
|
"Flags used by the assembler during debug builds.")
|
|
set (CMAKE_ASM${ASM_DIALECT}_FLAGS_MINSIZEREL "${CMAKE_ASM${ASM_DIALECT}_FLAGS_MINSIZEREL_INIT}" CACHE STRING
|
|
"Flags used by the assembler during release minsize builds.")
|
|
set (CMAKE_ASM${ASM_DIALECT}_FLAGS_RELEASE "${CMAKE_ASM${ASM_DIALECT}_FLAGS_RELEASE_INIT}" CACHE STRING
|
|
"Flags used by the assembler during release builds.")
|
|
set (CMAKE_ASM${ASM_DIALECT}_FLAGS_RELWITHDEBINFO "${CMAKE_ASM${ASM_DIALECT}_FLAGS_RELWITHDEBINFO_INIT}" CACHE STRING
|
|
"Flags used by the assembler during Release with Debug Info builds.")
|
|
endif()
|
|
|
|
mark_as_advanced(CMAKE_ASM${ASM_DIALECT}_FLAGS
|
|
CMAKE_ASM${ASM_DIALECT}_FLAGS_DEBUG
|
|
CMAKE_ASM${ASM_DIALECT}_FLAGS_MINSIZEREL
|
|
CMAKE_ASM${ASM_DIALECT}_FLAGS_RELEASE
|
|
CMAKE_ASM${ASM_DIALECT}_FLAGS_RELWITHDEBINFO
|
|
)
|
|
|
|
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT)
|
|
set(CMAKE_ASM${ASM_DIALECT}_COMPILE_OBJECT "<CMAKE_ASM${ASM_DIALECT}_COMPILER> <DEFINES> <INCLUDES> <FLAGS> -o <OBJECT> -c <SOURCE>")
|
|
endif()
|
|
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_CREATE_STATIC_LIBRARY)
|
|
set(CMAKE_ASM${ASM_DIALECT}_CREATE_STATIC_LIBRARY
|
|
"<CMAKE_AR> cr <TARGET> <LINK_FLAGS> <OBJECTS> "
|
|
"<CMAKE_RANLIB> <TARGET> ")
|
|
endif()
|
|
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_LINK_EXECUTABLE)
|
|
set(CMAKE_ASM${ASM_DIALECT}_LINK_EXECUTABLE
|
|
"<CMAKE_ASM${ASM_DIALECT}_COMPILER> <FLAGS> <CMAKE_ASM${ASM_DIALECT}_LINK_FLAGS> <LINK_FLAGS> <OBJECTS> -o <TARGET> <LINK_LIBRARIES>")
|
|
endif()
|
|
|
|
if(NOT CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG)
|
|
set(CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG ${CMAKE_SHARED_LIBRARY_RUNTIME_ASM${ASM_DIALECT}_FLAG})
|
|
endif()
|
|
|
|
if(NOT CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP)
|
|
set(CMAKE_EXECUTABLE_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP ${CMAKE_SHARED_LIBRARY_RUNTIME_ASM${ASM_DIALECT}_FLAG_SEP})
|
|
endif()
|
|
|
|
if(NOT CMAKE_EXECUTABLE_RPATH_LINK_ASM${ASM_DIALECT}_FLAG)
|
|
set(CMAKE_EXECUTABLE_RPATH_LINK_ASM${ASM_DIALECT}_FLAG ${CMAKE_SHARED_LIBRARY_RPATH_LINK_ASM${ASM_DIALECT}_FLAG})
|
|
endif()
|
|
|
|
# to be done
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_CREATE_SHARED_LIBRARY)
|
|
set(CMAKE_ASM${ASM_DIALECT}_CREATE_SHARED_LIBRARY)
|
|
endif()
|
|
|
|
if(NOT CMAKE_ASM${ASM_DIALECT}_CREATE_SHARED_MODULE)
|
|
set(CMAKE_ASM${ASM_DIALECT}_CREATE_SHARED_MODULE)
|
|
endif()
|
|
|
|
|
|
set(CMAKE_ASM${ASM_DIALECT}_INFOMATION_LOADED 1)
|
|
|