From bd728f6feeab10db189e82d3100c9df9ee64ad5c Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Fri, 17 Aug 2012 20:09:43 +0200
Subject: [PATCH 1/8] Add a return-after-error if an old Qt is found.

No need for an else after a return.
---
 Source/QtDialog/CMakeLists.txt | 207 ++++++++++++++++-----------------
 1 file changed, 103 insertions(+), 104 deletions(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 0969aea01..221e4d25c 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -15,109 +15,108 @@ find_package(Qt4 REQUIRED)
 
 if(NOT QT4_FOUND)
   message(SEND_ERROR "Failed to find Qt 4.4 or greater.")
-else()
-
-  include(${QT_USE_FILE})
-  set(CMAKE_PACKAGE_QTGUI TRUE)
-  set(SRCS
-    AddCacheEntry.cxx
-    AddCacheEntry.h
-    CMakeSetup.cxx
-    CMakeSetupDialog.cxx
-    CMakeSetupDialog.h
-    FirstConfigure.cxx
-    FirstConfigure.h
-    QCMake.cxx
-    QCMake.h
-    QCMakeCacheView.cxx
-    QCMakeCacheView.h
-    QCMakeWidgets.cxx
-    QCMakeWidgets.h
-    QMacInstallDialog.cxx
-    QMacInstallDialog.h
-    )
-  QT4_WRAP_UI(UI_SRCS
-    CMakeSetupDialog.ui
-    Compilers.ui
-    CrossCompiler.ui
-    AddCacheEntry.ui
-    MacInstallDialog.ui
-    )
-  QT4_WRAP_CPP(MOC_SRCS
-    AddCacheEntry.h
-    Compilers.h
-    CMakeSetupDialog.h
-    FirstConfigure.h
-    QCMake.h
-    QCMakeCacheView.h
-    QCMakeWidgets.h
-    QMacInstallDialog.h
-    )
-  QT4_ADD_RESOURCES(RC_SRCS CMakeSetup.qrc)
-
-  set(SRCS ${SRCS} ${UI_SRCS} ${MOC_SRCS} ${RC_SRCS})
-  if(Q_WS_WIN)
-    set(SRCS ${SRCS} CMakeSetup.rc)
-  endif()
-  if(Q_WS_MAC)
-    set(SRCS ${SRCS} CMakeSetup.icns)
-    set(MACOSX_BUNDLE_ICON_FILE CMakeSetup.icns)
-    set_source_files_properties(CMakeSetup.icns PROPERTIES
-      MACOSX_PACKAGE_LOCATION Resources)
-  endif()
-
-  include_directories(${CMAKE_CURRENT_BINARY_DIR})
-  include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-
-  add_executable(cmake-gui WIN32 MACOSX_BUNDLE ${SRCS})
-  target_link_libraries(cmake-gui CMakeLib ${QT_QTMAIN_LIBRARY} ${QT_LIBRARIES})
-  if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 2.4)
-    if(APPLE)
-      set_target_properties(cmake-gui PROPERTIES
-       OUTPUT_NAME ${CMAKE_BUNDLE_NAME})
-    endif()
-    set(CMAKE_INSTALL_DESTINATION_ARGS
-      BUNDLE DESTINATION "${CMAKE_BUNDLE_LOCATION}")
-  endif()
-
-  install(TARGETS cmake-gui RUNTIME DESTINATION bin ${CMAKE_INSTALL_DESTINATION_ARGS})
-
-  if(UNIX)
-    # install a desktop file so CMake appears in the application start menu
-    # with an icon
-    install(FILES CMake.desktop DESTINATION share/applications )
-    install(FILES CMakeSetup32.png DESTINATION share/pixmaps )
-    install(FILES cmakecache.xml DESTINATION share/mime/packages )
-  endif()
-
-  if(APPLE)
-    set(CMAKE_POSTFLIGHT_SCRIPT
-      "${CMake_BINARY_DIR}/Source/QtDialog/postflight.sh")
-    set(CMAKE_POSTUPGRADE_SCRIPT
-      "${CMake_BINARY_DIR}/Source/QtDialog/postupgrade.sh")
-    configure_file("${CMake_SOURCE_DIR}/Source/QtDialog/postflight.sh.in"
-      "${CMake_BINARY_DIR}/Source/QtDialog/postflight.sh")
-    configure_file("${CMake_SOURCE_DIR}/Source/QtDialog/postupgrade.sh.in"
-      "${CMake_BINARY_DIR}/Source/QtDialog/postupgrade.sh")
-    install(CODE "execute_process(COMMAND ln -s \"../MacOS/${CMAKE_BUNDLE_NAME}\" cmake-gui
-                  WORKING_DIRECTORY \$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/bin)")
-  endif()
-
-  if(APPLE OR WIN32)
-    # install rules for including 3rd party libs such as Qt
-    # if a system Qt is used (e.g. installed in /usr/lib/), it will not be included in the installation
-    set(fixup_exe "\$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/bin/cmake-gui${CMAKE_EXECUTABLE_SUFFIX}")
-    if(APPLE)
-      set(fixup_exe "\$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/MacOS/${CMAKE_BUNDLE_NAME}")
-    endif()
-    install(CODE "
-      include(\"${CMake_SOURCE_DIR}/Modules/BundleUtilities.cmake\")
-      set(BU_CHMOD_BUNDLE_ITEMS ON)
-      fixup_bundle(\"${fixup_exe}\" \"\" \"${QT_LIBRARY_DIR};${QT_BINARY_DIR}\")
-    ")
-  endif()
-
-  configure_file("${QtDialog_SOURCE_DIR}/QtDialogCPack.cmake.in"
-    "${QtDialog_BINARY_DIR}/QtDialogCPack.cmake" @ONLY)
+  return()
 endif()
 
+include(${QT_USE_FILE})
+set(CMAKE_PACKAGE_QTGUI TRUE)
+set(SRCS
+  AddCacheEntry.cxx
+  AddCacheEntry.h
+  CMakeSetup.cxx
+  CMakeSetupDialog.cxx
+  CMakeSetupDialog.h
+  FirstConfigure.cxx
+  FirstConfigure.h
+  QCMake.cxx
+  QCMake.h
+  QCMakeCacheView.cxx
+  QCMakeCacheView.h
+  QCMakeWidgets.cxx
+  QCMakeWidgets.h
+  QMacInstallDialog.cxx
+  QMacInstallDialog.h
+  )
+QT4_WRAP_UI(UI_SRCS
+  CMakeSetupDialog.ui
+  Compilers.ui
+  CrossCompiler.ui
+  AddCacheEntry.ui
+  MacInstallDialog.ui
+  )
+QT4_WRAP_CPP(MOC_SRCS
+  AddCacheEntry.h
+  Compilers.h
+  CMakeSetupDialog.h
+  FirstConfigure.h
+  QCMake.h
+  QCMakeCacheView.h
+  QCMakeWidgets.h
+  QMacInstallDialog.h
+  )
+QT4_ADD_RESOURCES(RC_SRCS CMakeSetup.qrc)
+
+set(SRCS ${SRCS} ${UI_SRCS} ${MOC_SRCS} ${RC_SRCS})
+if(Q_WS_WIN)
+  set(SRCS ${SRCS} CMakeSetup.rc)
+endif()
+if(Q_WS_MAC)
+  set(SRCS ${SRCS} CMakeSetup.icns)
+  set(MACOSX_BUNDLE_ICON_FILE CMakeSetup.icns)
+  set_source_files_properties(CMakeSetup.icns PROPERTIES
+    MACOSX_PACKAGE_LOCATION Resources)
+endif()
+
+include_directories(${CMAKE_CURRENT_BINARY_DIR})
+include_directories(${CMAKE_CURRENT_SOURCE_DIR})
+
+add_executable(cmake-gui WIN32 MACOSX_BUNDLE ${SRCS})
+target_link_libraries(cmake-gui CMakeLib ${QT_QTMAIN_LIBRARY} ${QT_LIBRARIES})
+if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 2.4)
+  if(APPLE)
+    set_target_properties(cmake-gui PROPERTIES
+      OUTPUT_NAME ${CMAKE_BUNDLE_NAME})
+  endif()
+  set(CMAKE_INSTALL_DESTINATION_ARGS
+    BUNDLE DESTINATION "${CMAKE_BUNDLE_LOCATION}")
+endif()
+
+install(TARGETS cmake-gui RUNTIME DESTINATION bin ${CMAKE_INSTALL_DESTINATION_ARGS})
+
+if(UNIX)
+  # install a desktop file so CMake appears in the application start menu
+  # with an icon
+  install(FILES CMake.desktop DESTINATION share/applications )
+  install(FILES CMakeSetup32.png DESTINATION share/pixmaps )
+  install(FILES cmakecache.xml DESTINATION share/mime/packages )
+endif()
+
+if(APPLE)
+  set(CMAKE_POSTFLIGHT_SCRIPT
+    "${CMake_BINARY_DIR}/Source/QtDialog/postflight.sh")
+  set(CMAKE_POSTUPGRADE_SCRIPT
+    "${CMake_BINARY_DIR}/Source/QtDialog/postupgrade.sh")
+  configure_file("${CMake_SOURCE_DIR}/Source/QtDialog/postflight.sh.in"
+    "${CMake_BINARY_DIR}/Source/QtDialog/postflight.sh")
+  configure_file("${CMake_SOURCE_DIR}/Source/QtDialog/postupgrade.sh.in"
+    "${CMake_BINARY_DIR}/Source/QtDialog/postupgrade.sh")
+  install(CODE "execute_process(COMMAND ln -s \"../MacOS/${CMAKE_BUNDLE_NAME}\" cmake-gui
+                WORKING_DIRECTORY \$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/bin)")
+endif()
+
+if(APPLE OR WIN32)
+  # install rules for including 3rd party libs such as Qt
+  # if a system Qt is used (e.g. installed in /usr/lib/), it will not be included in the installation
+  set(fixup_exe "\$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/bin/cmake-gui${CMAKE_EXECUTABLE_SUFFIX}")
+  if(APPLE)
+    set(fixup_exe "\$ENV{DESTDIR}\${CMAKE_INSTALL_PREFIX}/MacOS/${CMAKE_BUNDLE_NAME}")
+  endif()
+  install(CODE "
+    include(\"${CMake_SOURCE_DIR}/Modules/BundleUtilities.cmake\")
+    set(BU_CHMOD_BUNDLE_ITEMS ON)
+    fixup_bundle(\"${fixup_exe}\" \"\" \"${QT_LIBRARY_DIR};${QT_BINARY_DIR}\")
+  ")
+endif()
+
+configure_file("${QtDialog_SOURCE_DIR}/QtDialogCPack.cmake.in"
+  "${QtDialog_BINARY_DIR}/QtDialogCPack.cmake" @ONLY)

From 8ab312b6930c52a8f04688d8834383be4f09f5d5 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Thu, 23 Feb 2012 12:33:11 +0100
Subject: [PATCH 2/8] Use CMake platform variables instead of Qt ones.

The Qt ones no longer exist in Qt 5.
---
 Source/QtDialog/CMakeLists.txt | 4 ++--
 1 file changed, 2 insertions(+), 2 deletions(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 221e4d25c..00fc9faf2 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -57,10 +57,10 @@ QT4_WRAP_CPP(MOC_SRCS
 QT4_ADD_RESOURCES(RC_SRCS CMakeSetup.qrc)
 
 set(SRCS ${SRCS} ${UI_SRCS} ${MOC_SRCS} ${RC_SRCS})
-if(Q_WS_WIN)
+if(WIN32)
   set(SRCS ${SRCS} CMakeSetup.rc)
 endif()
-if(Q_WS_MAC)
+if(APPLE)
   set(SRCS ${SRCS} CMakeSetup.icns)
   set(MACOSX_BUNDLE_ICON_FILE CMakeSetup.icns)
   set_source_files_properties(CMakeSetup.icns PROPERTIES

From 0b6625c605b95ef7e936717e946906d422d3d4f7 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Fri, 17 Aug 2012 20:24:14 +0200
Subject: [PATCH 3/8] Move variable setting down to where it relates to.

---
 Source/QtDialog/CMakeLists.txt | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 00fc9faf2..625e6d16d 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -19,7 +19,6 @@ if(NOT QT4_FOUND)
 endif()
 
 include(${QT_USE_FILE})
-set(CMAKE_PACKAGE_QTGUI TRUE)
 set(SRCS
   AddCacheEntry.cxx
   AddCacheEntry.h
@@ -118,5 +117,6 @@ if(APPLE OR WIN32)
   ")
 endif()
 
+set(CMAKE_PACKAGE_QTGUI TRUE)
 configure_file("${QtDialog_SOURCE_DIR}/QtDialogCPack.cmake.in"
   "${QtDialog_BINARY_DIR}/QtDialogCPack.cmake" @ONLY)

From 32a572564a94380a543593f9568d34fc2c4a8b70 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Fri, 17 Aug 2012 20:48:15 +0200
Subject: [PATCH 4/8] Remove an if which is always true.

CMake based CMake build requires version 2.8.2 as of version 2.8.9.
---
 Source/QtDialog/CMakeLists.txt | 13 ++++++-------
 1 file changed, 6 insertions(+), 7 deletions(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 625e6d16d..1eaa8dcbb 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -71,14 +71,13 @@ include_directories(${CMAKE_CURRENT_SOURCE_DIR})
 
 add_executable(cmake-gui WIN32 MACOSX_BUNDLE ${SRCS})
 target_link_libraries(cmake-gui CMakeLib ${QT_QTMAIN_LIBRARY} ${QT_LIBRARIES})
-if(${CMAKE_MAJOR_VERSION}.${CMAKE_MINOR_VERSION} GREATER 2.4)
-  if(APPLE)
-    set_target_properties(cmake-gui PROPERTIES
-      OUTPUT_NAME ${CMAKE_BUNDLE_NAME})
-  endif()
-  set(CMAKE_INSTALL_DESTINATION_ARGS
-    BUNDLE DESTINATION "${CMAKE_BUNDLE_LOCATION}")
+
+if(APPLE)
+  set_target_properties(cmake-gui PROPERTIES
+    OUTPUT_NAME ${CMAKE_BUNDLE_NAME})
 endif()
+set(CMAKE_INSTALL_DESTINATION_ARGS
+  BUNDLE DESTINATION "${CMAKE_BUNDLE_LOCATION}")
 
 install(TARGETS cmake-gui RUNTIME DESTINATION bin ${CMAKE_INSTALL_DESTINATION_ARGS})
 

From 430ba9faef26d66e2fb3ffb938122b62f627562d Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Fri, 17 Aug 2012 20:37:54 +0200
Subject: [PATCH 5/8] Use add_subdirectory instead of the obsolete subdirs.

---
 Source/CMakeLists.txt | 2 +-
 1 file changed, 1 insertion(+), 1 deletion(-)

diff --git a/Source/CMakeLists.txt b/Source/CMakeLists.txt
index e79689b08..242470d7a 100644
--- a/Source/CMakeLists.txt
+++ b/Source/CMakeLists.txt
@@ -548,7 +548,7 @@ endif()
 # Qt GUI
 option(BUILD_QtDialog "Build Qt dialog for CMake" FALSE)
 if(BUILD_QtDialog)
-  subdirs(QtDialog)
+  add_subdirectory(QtDialog)
 endif()
 
 include (${CMake_BINARY_DIR}/Source/LocalUserOptions.cmake OPTIONAL)

From 066e85893ffa3492e4247e59a80ee1de67babef5 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Fri, 17 Aug 2012 20:25:51 +0200
Subject: [PATCH 6/8] Replace two include_directories with a setting.

---
 Source/QtDialog/CMakeLists.txt | 3 +--
 1 file changed, 1 insertion(+), 2 deletions(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 1eaa8dcbb..51e61d0cb 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -66,8 +66,7 @@ if(APPLE)
     MACOSX_PACKAGE_LOCATION Resources)
 endif()
 
-include_directories(${CMAKE_CURRENT_BINARY_DIR})
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
+set(CMAKE_INCLUDE_CURRENT_DIR ON)
 
 add_executable(cmake-gui WIN32 MACOSX_BUNDLE ${SRCS})
 target_link_libraries(cmake-gui CMakeLib ${QT_QTMAIN_LIBRARY} ${QT_LIBRARIES})

From 717f31a877e701b801043b893c97f4a186f93739 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Thu, 23 Feb 2012 12:35:53 +0100
Subject: [PATCH 7/8] Compile with both Qt4 and Qt5.

---
 Source/QtDialog/QCMake.cxx | 4 ++++
 1 file changed, 4 insertions(+)

diff --git a/Source/QtDialog/QCMake.cxx b/Source/QtDialog/QCMake.cxx
index a2b1567bf..0d0118164 100644
--- a/Source/QtDialog/QCMake.cxx
+++ b/Source/QtDialog/QCMake.cxx
@@ -348,7 +348,11 @@ void QCMake::interrupt()
 bool QCMake::interruptCallback(void* cd)
 {
   QCMake* self = reinterpret_cast<QCMake*>(cd);
+#if QT_VERSION < QT_VERSION_CHECK(5, 0, 0)
   return self->InterruptFlag;
+#else
+  return self->InterruptFlag.load();
+#endif
 }
 
 void QCMake::progressCallback(const char* msg, float percent, void* cd)

From 25a4f5675490d9311db271942ecd1781de5f3558 Mon Sep 17 00:00:00 2001
From: Stephen Kelly <steveire@gmail.com>
Date: Thu, 23 Feb 2012 12:40:38 +0100
Subject: [PATCH 8/8] Build with Qt5 if it is found.

---
 Source/QtDialog/CMakeLists.txt | 31 ++++++++++++++++++++++++-------
 1 file changed, 24 insertions(+), 7 deletions(-)

diff --git a/Source/QtDialog/CMakeLists.txt b/Source/QtDialog/CMakeLists.txt
index 51e61d0cb..a1ffa2076 100644
--- a/Source/QtDialog/CMakeLists.txt
+++ b/Source/QtDialog/CMakeLists.txt
@@ -9,16 +9,33 @@
 # implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
 # See the License for more information.
 #=============================================================================
-project(QtDialog)
-set(QT_MIN_VERSION "4.4.0")
-find_package(Qt4 REQUIRED)
 
-if(NOT QT4_FOUND)
-  message(SEND_ERROR "Failed to find Qt 4.4 or greater.")
-  return()
+project(QtDialog)
+find_package(Qt5Widgets QUIET)
+if (Qt5Widgets_FOUND)
+  include_directories(${Qt5Widgets_INCLUDE_DIRS})
+  add_definitions(${Qt5Widgets_DEFINITONS})
+  macro(qt4_wrap_ui)
+    qt5_wrap_ui(${ARGN})
+  endmacro()
+  macro(qt4_wrap_cpp)
+    qt5_wrap_cpp(${ARGN})
+  endmacro()
+  macro(qt4_add_resources)
+    qt5_add_resources(${ARGN})
+  endmacro()
+  set(QT_LIBRARIES ${Qt5Widgets_LIBRARIES})
+else()
+  set(QT_MIN_VERSION "4.4.0")
+  find_package(Qt4 REQUIRED)
+  if(NOT QT4_FOUND)
+    message(SEND_ERROR "Failed to find Qt 4.4 or greater.")
+    return()
+  endif()
+
+  include(${QT_USE_FILE})
 endif()
 
-include(${QT_USE_FILE})
 set(SRCS
   AddCacheEntry.cxx
   AddCacheEntry.h