From 680cff0b9fdb17758c8334267f5fa4913ae39f43 Mon Sep 17 00:00:00 2001
From: Alin Elena <alinm.elena@gmail.com>
Date: Wed, 10 Oct 2007 17:47:37 -0400
Subject: [PATCH] ENH: FindBLAS.cmake and FindLAPACK.cmake modules added. They
 locate various implementations of blas and lapack libraries.
 CheckFortranFunctionExists.cmake provides a test function to check if the
 library is usabale. I have also changed the -KPIC flag to -fPIC in
 Linux-ifort.cmake.

---
 Modules/CheckFortranFunctionExists.cmake |  50 +++++
 Modules/FindBLAS.cmake                   | 273 +++++++++++++++++++++++
 Modules/FindLAPACK.cmake                 | 180 +++++++++++++++
 Modules/Platform/Linux-ifort.cmake       |   2 +-
 4 files changed, 504 insertions(+), 1 deletion(-)
 create mode 100644 Modules/CheckFortranFunctionExists.cmake
 create mode 100644 Modules/FindBLAS.cmake
 create mode 100644 Modules/FindLAPACK.cmake

diff --git a/Modules/CheckFortranFunctionExists.cmake b/Modules/CheckFortranFunctionExists.cmake
new file mode 100644
index 000000000..4106a0693
--- /dev/null
+++ b/Modules/CheckFortranFunctionExists.cmake
@@ -0,0 +1,50 @@
+# - Check if the Fortran function exists.
+# CHECK_FORTRAN_FUNCTION_EXISTS(FUNCTION VARIABLE)
+# - macro which checks if the Fortran function exists
+#  FUNCTION - the name of the Fortran function
+#  VARIABLE - variable to store the result
+#
+# The following variables may be set before calling this macro to
+# modify the way the check is run:
+#
+#  CMAKE_REQUIRED_LIBRARIES = list of libraries to link
+#
+
+macro(CHECK_FORTRAN_FUNCTION_EXISTS FUNCTION VARIABLE)
+  if(NOT DEFINED ${VARIABLE})
+    message(STATUS "Looking for Fortran ${FUNCTION}")
+    if(CMAKE_REQUIRED_LIBRARIES)
+      set(CHECK_FUNCTION_EXISTS_ADD_LIBRARIES
+        "-DLINK_LIBRARIES:STRING=${CMAKE_REQUIRED_LIBRARIES}")
+    else(CMAKE_REQUIRED_LIBRARIES)
+      set(CHECK_FUNCTION_EXISTS_ADD_LIBRARIES)
+    endif(CMAKE_REQUIRED_LIBRARIES)
+    FILE(WRITE
+    ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompiler.f
+    "
+      program TESTFortran
+      external ${FUNCTION}
+      end
+    "
+    )
+    try_compile(${VARIABLE}
+    ${CMAKE_BINARY_DIR}
+    ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeTmp/testFortranCompiler.f
+    CMAKE_FLAGS "${CHECK_FUNCTION_EXISTS_ADD_LIBRARIES}"
+    OUTPUT_VARIABLE OUTPUT
+    )
+    if(${VARIABLE})
+      set(${VARIABLE} 1 CACHE INTERNAL "Have Fortran function ${FUNCTION}")
+      message(STATUS "Looking for Fortran ${FUNCTION} - found")
+      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeOutput.log 
+        "Determining if the Fortran ${FUNCTION} exists passed with the following output:\n"
+        "${OUTPUT}\n\n")
+    else(${VARIABLE})
+      message(STATUS "Looking for Fortran ${FUNCTION} - not found")
+      set(${VARIABLE} "" CACHE INTERNAL "Have Fortran function ${FUNCTION}")
+      file(APPEND ${CMAKE_BINARY_DIR}${CMAKE_FILES_DIRECTORY}/CMakeError.log 
+        "Determining if the Fortran ${FUNCTION} exists failed with the following output:\n"
+        "${OUTPUT}\n\n")
+    endif(${VARIABLE})
+  endif(NOT DEFINED ${VARIABLE})
+endmacro(CHECK_FORTRAN_FUNCTION_EXISTS)
diff --git a/Modules/FindBLAS.cmake b/Modules/FindBLAS.cmake
new file mode 100644
index 000000000..fb4805ff3
--- /dev/null
+++ b/Modules/FindBLAS.cmake
@@ -0,0 +1,273 @@
+# - Find BLAS library
+# This module finds an installed fortran library that implements the BLAS 
+# linear-algebra interface (see http://www.netlib.org/blas/).  
+# The list of libraries searched for is taken
+# from the autoconf macro file, acx_blas.m4 (distributed at
+# http://ac-archive.sourceforge.net/ac-archive/acx_blas.html).
+#
+# This module sets the following variables:
+#  BLAS_FOUND - set to true if a library implementing the BLAS interface
+#    is found
+#  BLAS_LINKER_FLAGS - uncached list of required linker flags (excluding -l
+#    and -L).
+#  BLAS_LIBRARIES - uncached list of libraries (using full path name) to 
+#    link against to use BLAS
+#
+
+include(CheckFortranFunctionExists)
+
+macro(Check_Fortran_Libraries LIBRARIES _prefix _name _flags _list)
+# This macro checks for the existence of the combination of fortran libraries
+# given by _list.  If the combination is found, this macro checks (using the 
+# Check_Fortran_Function_Exists macro) whether can link against that library
+# combination using the name of a routine given by _name using the linker
+# flags given by _flags.  If the combination of libraries is found and passes
+# the link test, LIBRARIES is set to the list of complete library paths that
+# have been found.  Otherwise, LIBRARIES is set to FALSE.
+ 
+# N.B. _prefix is the prefix applied to the names of all cached variables that
+# are generated internally and marked advanced by this macro.
+
+set(_libraries_work TRUE)
+set(${LIBRARIES})
+set(_combined_name)
+foreach(_library ${_list})
+  set(_combined_name ${_combined_name}_${_library})
+
+  if(_libraries_work)
+    
+   if ( APPLE ) 
+    find_library(${_prefix}_${_library}_LIBRARY
+    NAMES ${_library}
+    PATHS /usr/local/lib /usr/lib /usr/local/lib64 /usr/lib64 ENV DYLD_LIBRARY_PATH 
+    )
+   
+   else ( APPLE )
+    find_library(${_prefix}_${_library}_LIBRARY
+    NAMES ${_library}
+    PATHS /usr/local/lib /usr/lib /usr/local/lib64 /usr/lib64 ENV LD_LIBRARY_PATH 
+    )
+   endif( APPLE )
+    mark_as_advanced(${_prefix}_${_library}_LIBRARY)
+    set(${LIBRARIES} ${${LIBRARIES}} ${${_prefix}_${_library}_LIBRARY})
+    set(_libraries_work ${${_prefix}_${_library}_LIBRARY})
+  endif(_libraries_work)
+endforeach(_library ${_list})
+if(_libraries_work)
+  # Test this combination of libraries.
+  set(CMAKE_REQUIRED_LIBRARIES ${_flags} ${${LIBRARIES}})
+  #message("DEBUG: CMAKE_REQUIRED_LIBRARIES = ${CMAKE_REQUIRED_LIBRARIES}")
+  check_fortran_function_exists(${_name} ${_prefix}${_combined_name}_WORKS)
+  set(CMAKE_REQUIRED_LIBRARIES)
+  mark_as_advanced(${_prefix}${_combined_name}_WORKS)
+  set(_libraries_work ${${_prefix}${_combined_name}_WORKS})
+endif(_libraries_work)
+if(NOT _libraries_work)
+  set(${LIBRARIES} FALSE)
+endif(NOT _libraries_work)
+#message("DEBUG: ${LIBRARIES} = ${${LIBRARIES}}")
+endmacro(Check_Fortran_Libraries)
+
+set(BLAS_LINKER_FLAGS)
+set(BLAS_LIBRARIES)
+
+
+
+if(NOT BLAS_LIBRARIES)
+  # BLAS in ATLAS library? (http://math-atlas.sourceforge.net/)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  cblas_dgemm
+  ""
+  "cblas;f77blas;atlas"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in PhiPACK libraries? (requires generic BLAS lib, too)
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "sgemm;dgemm;blas"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in Alpha CXML library?
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "cxml"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in Alpha DXML library? (now called CXML, see above)
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "dxml"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in Sun Performance library?
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  "-xlic_lib=sunperf"
+  "sunperf;sunmath"
+  )
+  if(BLAS_LIBRARIES)
+    set(BLAS_LINKER_FLAGS "-xlic_lib=sunperf")
+  endif(BLAS_LIBRARIES)
+  
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in SCSL library?  (SGI/Cray Scientific Library)
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "scsl"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in SGIMATH library?
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "complib.sgimath"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+# BLAS in IBM ESSL library? (requires generic BLAS lib, too)
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "essl;blas"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+
+
+
+# BLAS in intel mkl library? (shared)
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "mkl;guide;pthread"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+#BLAS in intel mkl library? (static, 32bit)
+if(NOT BLAS_LIBRARIES)
+check_fortran_libraries(
+BLAS_LIBRARIES
+BLAS
+sgemm
+""
+"mkl_ia32;guide;pthread"
+)
+endif(NOT BLAS_LIBRARIES)
+
+#BLAS in intel mkl library? (static, em64t 64bit)
+if(NOT BLAS_LIBRARIES)
+check_fortran_libraries(
+BLAS_LIBRARIES
+BLAS
+sgemm
+""
+"mkl_em64t;guide;pthread"
+)
+endif(NOT BLAS_LIBRARIES)
+
+
+#BLAS in acml library? 
+if(NOT BLAS_LIBRARIES)
+check_fortran_libraries(
+BLAS_LIBRARIES
+BLAS
+sgemm
+""
+"acml"
+)
+endif(NOT BLAS_LIBRARIES)
+
+
+
+# Apple BLAS library?
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  cblas_dgemm
+  ""
+  "Accelerate"
+  )
+  
+  endif(NOT BLAS_LIBRARIES)
+  
+  if ( NOT BLAS_LIBRARIES )
+    check_fortran_libraries(
+    BLAS_LIBRARIES
+    BLAS
+    cblas_dgemm
+    ""
+    "vecLib"
+    )
+  endif ( NOT BLAS_LIBRARIES )
+
+
+# Generic BLAS library?
+if(NOT BLAS_LIBRARIES)
+  check_fortran_libraries(
+  BLAS_LIBRARIES
+  BLAS
+  sgemm
+  ""
+  "blas"
+  )
+endif(NOT BLAS_LIBRARIES)
+
+
+if(BLAS_LIBRARIES)
+  set(BLAS_FOUND TRUE)
+else(BLAS_LIBRARIES)
+  set(BLAS_FOUND FALSE)
+endif(BLAS_LIBRARIES)
+
+if(NOT BLAS_FIND_QUIETLY)
+  if(BLAS_FOUND)
+    message(STATUS "A library with BLAS API found.")
+  else(BLAS_FOUND)
+    if(BLAS_FIND_REQUIRED)
+      message(FATAL_ERROR 
+      "A required library with BLAS API not found. Please specify library location."
+      )
+    else(BLAS_FIND_REQUIRED)
+      message(STATUS
+      "A library with BLAS API not found. Please specify library location."
+      )
+    endif(BLAS_FIND_REQUIRED)
+  endif(BLAS_FOUND)
+endif(NOT BLAS_FIND_QUIETLY)
diff --git a/Modules/FindLAPACK.cmake b/Modules/FindLAPACK.cmake
new file mode 100644
index 000000000..7f838cd6d
--- /dev/null
+++ b/Modules/FindLAPACK.cmake
@@ -0,0 +1,180 @@
+# - Find LAPACK library
+# This module finds an installed fortran library that implements the LAPACK
+# linear-algebra interface (see http://www.netlib.org/lapack/).
+#
+# The approach follows that taken for the autoconf macro file, acx_lapack.m4
+# (distributed at http://ac-archive.sourceforge.net/ac-archive/acx_lapack.html).
+#
+# This module sets the following variables:
+#  LAPACK_FOUND - set to true if a library implementing the LAPACK interface
+#    is found
+#  LAPACK_LINKER_FLAGS - uncached list of required linker flags (excluding -l
+#    and -L).
+#  LAPACK_LIBRARIES - uncached list of libraries (using full path name) to 
+#    link against to use LAPACK
+#
+
+include(CheckFortranFunctionExists)
+set(LAPACK_FOUND FALSE)
+
+macro(Check_Lapack_Libraries LIBRARIES _prefix _name _flags _list _blas)
+# This macro checks for the existence of the combination of fortran libraries
+# given by _list.  If the combination is found, this macro checks (using the 
+# Check_Fortran_Function_Exists macro) whether can link against that library
+# combination using the name of a routine given by _name using the linker
+# flags given by _flags.  If the combination of libraries is found and passes
+# the link test, LIBRARIES is set to the list of complete library paths that
+# have been found.  Otherwise, LIBRARIES is set to FALSE.
+ 
+# N.B. _prefix is the prefix applied to the names of all cached variables that
+# are generated internally and marked advanced by this macro.
+
+set(_libraries_work TRUE)
+set(${LIBRARIES})
+set(_combined_name)
+foreach(_library ${_list})
+  set(_combined_name ${_combined_name}_${_library})
+
+  if(_libraries_work)
+  if(APPLE)
+    find_library(${_prefix}_${_library}_LIBRARY
+    NAMES ${_library}
+    PATHS /usr/local/lib /usr/lib /usr/local/lib64 /usr/lib64 ENV DYLD_LIBRARY_PATH
+    )
+    else(APPLE)
+        find_library(${_prefix}_${_library}_LIBRARY
+    NAMES ${_library}
+    PATHS /usr/local/lib /usr/lib /usr/local/lib64 /usr/lib64 ENV LD_LIBRARY_PATH
+    )
+    endif(APPLE)
+
+    mark_as_advanced(${_prefix}_${_library}_LIBRARY)
+    set(${LIBRARIES} ${${LIBRARIES}} ${${_prefix}_${_library}_LIBRARY})
+    set(_libraries_work ${${_prefix}_${_library}_LIBRARY})
+  endif(_libraries_work)
+endforeach(_library ${_list})
+
+if(_libraries_work)
+  # Test this combination of libraries.
+  set(CMAKE_REQUIRED_LIBRARIES ${_flags} ${${LIBRARIES}} ${_blas})
+  #message("DEBUG: CMAKE_REQUIRED_LIBRARIES = ${CMAKE_REQUIRED_LIBRARIES}")
+  check_fortran_function_exists(${_name} ${_prefix}${_combined_name}_WORKS)
+  set(CMAKE_REQUIRED_LIBRARIES)
+  mark_as_advanced(${_prefix}${_combined_name}_WORKS)
+  set(_libraries_work ${${_prefix}${_combined_name}_WORKS})
+  #message("DEBUG: ${LIBRARIES} = ${${LIBRARIES}}")
+endif(_libraries_work)
+
+if(NOT _libraries_work)
+  set(${LIBRARIES} FALSE)
+endif(NOT _libraries_work)
+
+endmacro(Check_Lapack_Libraries)
+
+
+set(LAPACK_LINKER_FLAGS)
+set(LAPACK_LIBRARIES)
+
+
+if(LAPACK_FIND_QUIETLY OR NOT LAPACK_FIND_REQUIRED)
+  find_package(BLAS)
+else(LAPACK_FIND_QUIETLY OR NOT LAPACK_FIND_REQUIRED)
+  find_package(BLAS REQUIRED)
+endif(LAPACK_FIND_QUIETLY OR NOT LAPACK_FIND_REQUIRED)
+
+if(BLAS_FOUND)
+  set(LAPACK_LINKER_FLAGS ${BLAS_LINKER_FLAGS})
+
+#intel lapack
+  if(NOT LAPACK_LIBRARIES)
+
+  check_lapack_libraries(
+  LAPACK_LIBRARIES
+  LAPACK
+  cheev
+  ""
+  "mkl_lapack"
+ "${BLAS_LIBRARIES}"
+  )
+  endif(NOT LAPACK_LIBRARIES)
+
+
+
+#acml lapack
+  if(NOT LAPACK_LIBRARIES)
+
+  check_lapack_libraries(
+  LAPACK_LIBRARIES
+  LAPACK
+  cheev
+  ""
+  "acml"
+ "${BLAS_LIBRARIES}"
+  )
+endif(NOT LAPACK_LIBRARIES)
+
+
+# Apple LAPACK library?
+if(NOT LAPACK_LIBRARIES)
+  check_lapack_libraries(
+  LAPACK_LIBRARIES
+  LAPACK
+  cheev
+  ""
+  "Accelerate"
+  "${BLAS_LIBRARIES}"
+  )
+  endif(NOT LAPACK_LIBRARIES)
+  
+  if ( NOT LAPACK_LIBRARIES )
+    check_lapack_libraries(
+    LAPACK_LIBRARIES
+    LAPACK
+    cheev
+    ""
+    "vecLib"
+    "${BLAS_LIBRARIES}"
+    )
+  endif ( NOT LAPACK_LIBRARIES )
+
+
+
+
+
+# Generic LAPACK library?
+  if ( NOT LAPACK_LIBRARIES )
+    check_lapack_libraries(
+    LAPACK_LIBRARIES
+    LAPACK
+    cheev
+    ""
+    "lapack"
+    "${BLAS_LIBRARIES}"
+    )
+  endif ( NOT LAPACK_LIBRARIES )
+
+else(BLAS_FOUND)
+  message(STATUS "LAPACK requires BLAS")
+endif(BLAS_FOUND)
+
+if(LAPACK_LIBRARIES)
+  set(LAPACK_FOUND TRUE)
+else(LAPACK_LIBRARIES)
+  set(LAPACK_FOUND FALSE)
+endif(LAPACK_LIBRARIES)
+
+if(NOT LAPACK_FIND_QUIETLY)
+  if(LAPACK_FOUND)
+    message(STATUS "A library with LAPACK API found.")
+  else(LAPACK_FOUND)
+    if(LAPACK_FIND_REQUIRED)
+      message(FATAL_ERROR 
+      "A required library with LAPACK API not found. Please specify library location."
+      )
+    else(LAPACK_FIND_REQUIRED)
+      message(STATUS
+      "A library with LAPACK API not found. Please specify library location."
+      )
+    endif(LAPACK_FIND_REQUIRED)
+  endif(LAPACK_FOUND)
+endif(NOT LAPACK_FIND_QUIETLY)
diff --git a/Modules/Platform/Linux-ifort.cmake b/Modules/Platform/Linux-ifort.cmake
index 6d6fcfb87..04dcd6242 100644
--- a/Modules/Platform/Linux-ifort.cmake
+++ b/Modules/Platform/Linux-ifort.cmake
@@ -1,5 +1,5 @@
 SET(CMAKE_DL_LIBS "dl")
-SET(CMAKE_SHARED_LIBRARY_Fortran_FLAGS "-KPIC")        
+SET(CMAKE_SHARED_LIBRARY_Fortran_FLAGS "-fPIC")        
 SET(CMAKE_SHARED_LIBRARY_CREATE_Fortran_FLAGS "-shared")
 SET(CMAKE_SHARED_LIBRARY_LINK_Fortran_FLAGS "-i_dynamic")  
 SET(CMAKE_SHARED_LIBRARY_RUNTIME_Fortran_FLAG "-Wl,-rpath,")