Merge topic 'WriteConfigVersionFile_2TemplateFiles'
c9761deImprove documentation for WriteBasicConfigVersionFile.cmake208bb90Set UNSUITABLE instead of not COMPATIBLEbb03c2dReally fix copyright noticed50a61aFix copyright notice4ba09bcAdd some tests for write_basic_config_version_file()02b1e4bAdd example to documentationd216a67Provide macro write_basic_config_version_file()
This commit is contained in:
David Cole
CMake Topic Stage
commit
674be27a7f
|
|
@ -0,0 +1,26 @@
|
|||
# This is a basic version file for the Config-mode of find_package().
|
||||
# It is used by WriteBasicConfigVersionFile.cmake as input file for configure_file()
|
||||
# to create a version-file which can be installed along a config.cmake file.
|
||||
#
|
||||
# The created file sets PACKAGE_VERSION_EXACT if the current version string and
|
||||
# the requested version string are exactly the same and it sets
|
||||
# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version.
|
||||
# The variable CVF_VERSION must be set before calling configure_file().
|
||||
|
||||
set(PACKAGE_VERSION "@CVF_VERSION@")
|
||||
|
||||
if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
|
||||
set(PACKAGE_VERSION_COMPATIBLE FALSE)
|
||||
else()
|
||||
set(PACKAGE_VERSION_COMPATIBLE TRUE)
|
||||
if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
|
||||
set(PACKAGE_VERSION_EXACT TRUE)
|
||||
endif()
|
||||
endif()
|
||||
|
||||
# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
|
||||
if(NOT "${CMAKE_SIZEOF_VOID_P}" STREQUAL "@CMAKE_SIZEOF_VOID_P@")
|
||||
math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
|
||||
set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
|
||||
set(PACKAGE_VERSION_UNSUITABLE TRUE)
|
||||
endif()
|
||||
|
|
@ -0,0 +1,41 @@
|
|||
# This is a basic version file for the Config-mode of find_package().
|
||||
# It is used by WriteBasicConfigVersionFile.cmake as input file for configure_file()
|
||||
# to create a version-file which can be installed along a config.cmake file.
|
||||
#
|
||||
# The created file sets PACKAGE_VERSION_EXACT if the current version string and
|
||||
# the requested version string are exactly the same and it sets
|
||||
# PACKAGE_VERSION_COMPATIBLE if the current version is >= requested version,
|
||||
# but only if the requested major version is the same as the current one.
|
||||
# The variable CVF_VERSION must be set before calling configure_file().
|
||||
|
||||
|
||||
set(PACKAGE_VERSION "@CVF_VERSION@")
|
||||
|
||||
if("${PACKAGE_VERSION}" VERSION_LESS "${PACKAGE_FIND_VERSION}" )
|
||||
set(PACKAGE_VERSION_COMPATIBLE FALSE)
|
||||
else()
|
||||
|
||||
if("@CVF_VERSION@" MATCHES "^([0-9]+)\\.")
|
||||
set(CVF_VERSION_MAJOR "${CMAKE_MATCH_1}")
|
||||
else()
|
||||
set(CVF_VERSION_MAJOR "@CVF_VERSION@")
|
||||
endif()
|
||||
|
||||
if("${PACKAGE_FIND_VERSION_MAJOR}" STREQUAL "${CVF_VERSION_MAJOR}")
|
||||
set(PACKAGE_VERSION_COMPATIBLE TRUE)
|
||||
else()
|
||||
set(PACKAGE_VERSION_COMPATIBLE FALSE)
|
||||
endif()
|
||||
|
||||
if( "${PACKAGE_FIND_VERSION}" STREQUAL "${PACKAGE_VERSION}")
|
||||
set(PACKAGE_VERSION_EXACT TRUE)
|
||||
endif()
|
||||
endif()
|
||||
|
||||
|
||||
# check that the installed version has the same 32/64bit-ness as the one which is currently searching:
|
||||
if(NOT "${CMAKE_SIZEOF_VOID_P}" STREQUAL "@CMAKE_SIZEOF_VOID_P@")
|
||||
math(EXPR installedBits "@CMAKE_SIZEOF_VOID_P@ * 8")
|
||||
set(PACKAGE_VERSION "${PACKAGE_VERSION} (${installedBits}bit)")
|
||||
set(PACKAGE_VERSION_UNSUITABLE TRUE)
|
||||
endif()
|
||||
|
|
@ -0,0 +1,69 @@
|
|||
# WRITE_BASIC_CONFIG_VERSION_FILE( filename VERSION major.minor.patch COMPATIBILITY (AnyNewerVersion|SameMajorVersion) )
|
||||
#
|
||||
# Writes a file for use as <package>ConfigVersion.cmake file to <filename>.
|
||||
# See the documentation of FIND_PACKAGE() for details on this.
|
||||
# filename is the output filename, it should be in the build tree.
|
||||
# major.minor.patch is the version number of the project to be installed
|
||||
# The COMPATIBILITY mode AnyNewerVersion means that the installed package version
|
||||
# will be considered compatible if it is newer or exactly the same as the requested version.
|
||||
# If SameMajorVersion is used instead, then the behaviour differs from AnyNewerVersion
|
||||
# in that the major version number must be the same as requested, e.g. version 2.0 will
|
||||
# not be considered compatible if 1.0 is requested.
|
||||
# If your project has more elaborated version matching rules, you will need to write your
|
||||
# own custom ConfigVersion.cmake file instead of using this macro.
|
||||
#
|
||||
# Example:
|
||||
# write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/FooConfigVersion.cmake
|
||||
# VERSION 1.2.3
|
||||
# COMPATIBILITY SameMajorVersion )
|
||||
# install(FILES ${CMAKE_CURRENT_BINARY_DIR}/FooConfigVersion.cmake
|
||||
# ${CMAKE_CURRENT_BINARY_DIR}/FooConfig.cmake
|
||||
# DESTINATION lib/cmake/Foo )
|
||||
#
|
||||
# Internally, this macro executes configure_file() to create the resulting
|
||||
# version file. Depending on the COMPATIBLITY, either the file
|
||||
# BasicConfigVersion-SameMajorVersion.cmake.in or BasicConfigVersion-AnyNewerVersion.cmake.in
|
||||
# is used. Please note that these two files are internal to CMake and you should
|
||||
# not call configure_file() on them yourself, but they can be used as starting
|
||||
# point to create more sophisticted custom ConfigVersion.cmake files.
|
||||
|
||||
#=============================================================================
|
||||
# Copyright 2008-2011 Alexander Neundorf, <neundorf@kde.org>
|
||||
# Copyright 2004-2009 Kitware, Inc.
|
||||
#
|
||||
# Distributed under the OSI-approved BSD License (the "License");
|
||||
# see accompanying file Copyright.txt for details.
|
||||
#
|
||||
# This software is distributed WITHOUT ANY WARRANTY; without even the
|
||||
# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
|
||||
# See the License for more information.
|
||||
#=============================================================================
|
||||
# (To distribute this file outside of CMake, substitute the full
|
||||
# License text for the above reference.)
|
||||
|
||||
include(CMakeParseArguments)
|
||||
|
||||
function(WRITE_BASIC_CONFIG_VERSION_FILE _filename)
|
||||
|
||||
set(options )
|
||||
set(oneValueArgs VERSION COMPATIBILITY )
|
||||
set(multiValueArgs )
|
||||
|
||||
cmake_parse_arguments(CVF "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
|
||||
|
||||
if(CVF_UNPARSED_ARGUMENTS)
|
||||
message(FATAL_ERROR "Unknown keywords given to WRITE_BASIC_CONFIG_VERSION_FILE(): \"${CVF_UNPARSED_ARGUMENTS}\"")
|
||||
endif(CVF_UNPARSED_ARGUMENTS)
|
||||
|
||||
set(versionTemplateFile "${CMAKE_ROOT}/Modules/BasicConfigVersion-${CVF_COMPATIBILITY}.cmake.in")
|
||||
if(NOT EXISTS "${versionTemplateFile}")
|
||||
message(FATAL_ERROR "Bad COMPATIBILITY value used for WRITE_BASIC_CONFIG_VERSION_FILE(): \"${CVF_COMPATIBILITY}\"")
|
||||
endif()
|
||||
|
||||
if("${CVF_VERSION}" STREQUAL "")
|
||||
message(FATAL_ERROR "No VERSION specified for WRITE_BASIC_CONFIG_VERSION_FILE()")
|
||||
endif()
|
||||
|
||||
configure_file("${versionTemplateFile}" "${_filename}" @ONLY)
|
||||
|
||||
endfunction(WRITE_BASIC_CONFIG_VERSION_FILE)
|
||||
|
|
@ -191,6 +191,9 @@ void cmFindPackageCommand::GenerateDocumentation()
|
|||
"\"<config-file>-version.cmake\" or \"<config-file>Version.cmake\". "
|
||||
"If no such version file is available then the configuration file "
|
||||
"is assumed to not be compatible with any requested version. "
|
||||
"A basic version file containing generic version matching code can be "
|
||||
"created using the macro write_basic_config_version_file(), see its "
|
||||
"documentation for more details. "
|
||||
"When a version file is found it is loaded to check the requested "
|
||||
"version number. "
|
||||
"The version file is loaded in a nested scope in which the following "
|
||||
|
|
|
|||
|
|
@ -303,3 +303,94 @@ SET(CMakeTestExportPackage_DIR "" CACHE FILEPATH
|
|||
"Wipe out find results for testing." FORCE)
|
||||
STRING(REGEX REPLACE "-.*$" "" version ${CMAKE_VERSION})
|
||||
FIND_PACKAGE(CMakeTestExportPackage 1.${version} EXACT REQUIRED)
|
||||
|
||||
#-----------------------------------------------------------------------------
|
||||
# Test write_basic_config_version_file().
|
||||
|
||||
include(WriteBasicConfigVersionFile)
|
||||
|
||||
write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/Foo123ConfigVersion.cmake
|
||||
VERSION 1.2.3
|
||||
COMPATIBILITY AnyNewerVersion)
|
||||
|
||||
set(PACKAGE_FIND_VERSION 2.3.4)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Foo123ConfigVersion.cmake)
|
||||
if(PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Found Foo123 with version 1.2.3, but 2.3.4 was requested !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 0.0.1)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Foo123ConfigVersion.cmake)
|
||||
if(NOT PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Did not find Foo123 with version 1.2.3 (0.0.1 was requested) !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 1.0.0)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Foo123ConfigVersion.cmake)
|
||||
if(NOT PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Did not find Foo123 with version 1.2.3 (1.0.0 was requested) !")
|
||||
endif()
|
||||
if(PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT set, although it should not be !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 1.2.3)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Foo123ConfigVersion.cmake)
|
||||
if(NOT PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Did not find Foo123 with version 1.2.3 (1.2.3 was requested) !")
|
||||
endif()
|
||||
if(NOT PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT not set, although it should be !")
|
||||
endif()
|
||||
|
||||
|
||||
#######################
|
||||
|
||||
write_basic_config_version_file(${CMAKE_CURRENT_BINARY_DIR}/Boo123ConfigVersion.cmake
|
||||
VERSION 1.2.3
|
||||
COMPATIBILITY SameMajorVersion)
|
||||
|
||||
set(PACKAGE_VERSION_EXACT FALSE)
|
||||
set(PACKAGE_FIND_VERSION 2.3.4)
|
||||
set(PACKAGE_FIND_VERSION_MAJOR 2)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Boo123ConfigVersion.cmake)
|
||||
if(PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Found Boo123 with version 1.2.3, but 2.3.4 was requested !")
|
||||
endif()
|
||||
if(PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT set, although it should not be !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 0.0.1)
|
||||
set(PACKAGE_FIND_VERSION_MAJOR 0)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Boo123ConfigVersion.cmake)
|
||||
if(PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Found Boo123 with version 1.2.3, but 0.0.1 was requested !")
|
||||
endif()
|
||||
if(PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT set, although it should not be !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 1.0.0)
|
||||
set(PACKAGE_FIND_VERSION_MAJOR 1)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Boo123ConfigVersion.cmake)
|
||||
if(NOT PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Did not find Boo123 with version 1.2.3 (1.0.0 was requested) !")
|
||||
endif()
|
||||
if(PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT set, although it should not be !")
|
||||
endif()
|
||||
|
||||
set(PACKAGE_FIND_VERSION 1.2.3)
|
||||
set(PACKAGE_FIND_VERSION_MAJOR 1)
|
||||
include(${CMAKE_CURRENT_BINARY_DIR}/Boo123ConfigVersion.cmake)
|
||||
if(NOT PACKAGE_VERSION_COMPATIBLE)
|
||||
message(SEND_ERROR "Did not find Boo123 with version 1.2.3 (1.2.3 was requested) !")
|
||||
endif()
|
||||
if(NOT PACKAGE_VERSION_EXACT)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_EXACT not set, although it should be !")
|
||||
endif()
|
||||
|
||||
if(PACKAGE_VERSION_UNSUITABLE)
|
||||
message(SEND_ERROR "PACKAGE_VERSION_UNSUITABLE set, but must not be !")
|
||||
endif()
|
||||
|
|
|
|||
Loading…
Reference in New Issue