Merge topic 'generate_export_header'

6a6393c Don't use a variable name that might be used in other files. 5ca8c56 Fix up verbatim code sections of the dox. 75596e6 Don't start a line with a dash(-) 826374a Remove blank line at the start of the file. 8b9b8e1 Add documentation about the prefix and no_deprecated options. 51bc63a Fix the feature of using a specific prefix for macros. 3449f6b Add quotes in case cmake is installed in a prefix with a space. 36d28f2 Fix Compiler id variable name. 99b2aab Disable the tests for Watcom. 7ac0ab1 Quote paths in case there is a space in one of them. 89108b9 Look for errors reported by PGI too. e0cc024 Add missing NO_EXPORT macro variant. 1b031d1 More consistency in the macro options. 03d60c7 Try to make the macros do almost nothing for Watcom. 6adeda9 Possibly fix configuration test on AIX. e253348 Possibly fix test on HPUX. 32eff0c Test for too-old-intel compilers. 42154ec Fix up the regex command for Intel. a147a06 Add some settings for non-truncation of test output. bf73e75 Hopefully add version extraction for Intel. aa4f0b6 Fix the version extraction regex for clang. a493d1a Test the correct cxx variable. b6ee2ee Comment the test assertion for now a9a8b9e Exclude win32 from hidden visibility checks. afae7a9 Start testing expected values for compiler flags. 1ae3365 Exclude PGI from exports and deprecated. f426496 Exclude cygwin from the hidden visibility feature. f84c7db Don't enable deprecated on old GCC 9672b33 Don't enable deprecated on HP. 10d8c44 Disable testing of deprecated macros. 97392a7d Fixup forgotten part of aed84517c9 2aeab4f Borland can't do deprecated. c41c68b Try to error on deprecated on Intel and SunCC. aed8451 Test for deprecated attribute before declspec. c448b09 Perform the -Werror test only once. fb88c6e Add some messaging output to make remaining issues findable. 01e9e98 Test -Werror instead of enabling it per compiler. 9aab2aa Expect the tests to pass if hidden visibilty is not enabled. 856bdb3 Don't change the expected build result based on the platform. df4615e Add the COMPILER_HAS_DEPRECATED only if it has a declspec variant 78a6e1c Exclude the XL compiler from the hidden-visibility test. e1f7ee3 Test for compiler features, instead of for specific platforms. 9554e10 Split the deprecated available check from setting macro values. 1590d5f Don't export methods on already exported classes. 750b67c Don't use hidden visibility on non-mingw windows either. 1f3be45 Make sure the hidden visibility variables never get set on MINGW. 399f415 Only set the deprecated attribute if hidden visibilty is enabled. 1c6b41b Remember to surround the other deprecated test in the Borland check. 3f7e036 Export deprecated free methods too. 7fa5592 Add some debug output to narrow down deprecation test issues 7924c1d Another attempt at fixing Borland. 50460ea Fix off-by-not in test for Borland. b443459 Use the correct project name compiletest not compilefail fc3772e Another attempt to fix the tests on Borland. bab4a22 Disable all export macros on Borland. cff9493 Only set the COMPILER_HAS_HIDDEN_VISIBILITY if GCC >= 4.2 af443b8 Set the CMAKE_RUNTIME_OUTPUT_DIRECTORY for windows builds. 61726f8 Only run the failure tests with gcc >= 4.2 002ddf2 Fix typo and tests failing as a result. 4443037 Fix tests with clang. ffaa127 Test expected no-op instead of aborting the build. 6aca0e2 Short-circuit the tests on unsupported compilers. d123bce Add some debug output. 3574b75 Simplify the compiler feature check c7a937b Simplify. We already know we have hidden visibility at this point. 3b188c8 Test for features, not specific compilers. 4718233 Remove the fatal_warnings option which is no longer used. b19911e Add missing licence header. 706ed2b Add a newline at the end of the file. 8963716 Add a newline at the end of the file. def0a54 Handle the case where the user changes the DEFINE_SYMBOL property. 3088070 Add the GenerateExportMacro with unit tests.
2011-09-01 15:14:01 -04:00 · 2011-09-01 15:14:01 -04:00 · 482a235bff
parent 28e1dc8fe0 6a6393c905
commit 482a235bff
23 changed files with 1298 additions and 0 deletions
--- a/Modules/CheckCXXCompilerFlag.cmake
+++ b/Modules/CheckCXXCompilerFlag.cmake
@ -34,6 +34,8 @@ MACRO (CHECK_CXX_COMPILER_FLAG _FLAG _RESULT)
     FAIL_REGEX "[Uu]nknown option"                         # HP
     FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
     FAIL_REGEX "command option .* is not recognized"       # XL
+     FAIL_REGEX "not supported in this configuration; ignored"       # AIX
+     FAIL_REGEX "File with unknown suffix passed to linker" # PGI
     )
   SET (CMAKE_REQUIRED_DEFINITIONS "${SAFE_CMAKE_REQUIRED_DEFINITIONS}")
 ENDMACRO (CHECK_CXX_COMPILER_FLAG)
--- a/Modules/GenerateExportHeader.cmake
+++ b/Modules/GenerateExportHeader.cmake
@ -0,0 +1,346 @@
+# - Function for generation of export macros for libraries
+# This module provides the function GENERATE_EXPORT_HEADER() and the
+# accompanying ADD_COMPILER_EXPORT_FLAGS() function.
+#
+# The GENERATE_EXPORT_HEADER function can be used to generate a file suitable
+# for preprocessor inclusion which contains EXPORT macros to be used in
+# library classes.
+#
+# GENERATE_EXPORT_HEADER( LIBRARY_TARGET
+#             [BASE_NAME <base_name>]
+#             [EXPORT_MACRO_NAME <export_macro_name>]
+#             [EXPORT_FILE_NAME <export_file_name>]
+#             [DEPRECATED_MACRO_NAME <deprecated_macro_name>]
+#             [NO_EXPORT_MACRO_NAME <no_export_macro_name>]
+#             [STATIC_DEFINE <static_define>]
+#             [NO_DEPRECATED_MACRO_NAME <no_deprecated_macro_name>]
+#             [DEFINE_NO_DEPRECATED]
+#             [PREFIX_NAME <prefix_name>]
+# )
+#
+# ADD_COMPILER_EXPORT_FLAGS( [FATAL_WARNINGS] )
+#
+# By default GENERATE_EXPORT_HEADER() generates macro names in a file name
+# determined by the name of the library. The ADD_COMPILER_EXPORT_FLAGS macro
+# adds -fvisibility=hidden to CMAKE_CXX_FLAGS if supported, and is a no-op on Windows
+# which does not need extra compiler flags for exporting support.
+#
+# This means that in the simplest case, users of these functions will be equivalent to:
+#
+#   add_compiler_export_flags()
+#   add_library(somelib someclass.cpp)
+#   generate_export_header(somelib)
+#   install(TARGETS somelib DESTINATION ${LIBRARY_INSTALL_DIR})
+#   install(FILES
+#    someclass.h
+#    ${PROJECT_BINARY_DIR}/somelib_export.h DESTINATION ${INCLUDE_INSTALL_DIR}
+#   )
+#
+# And in the ABI header files:
+#
+#   #include "somelib_export.h"
+#   class SOMELIB_EXPORT SomeClass {
+#     ...
+#   };
+#
+# The CMake fragment will generate a file in the ${CMAKE_CURRENT_BUILD_DIR} called
+# somelib_export.h containing the macros SOMELIB_EXPORT, SOMELIB_NO_EXPORT,
+# SOMELIB_DEPRECATED, SOMELIB_DEPRECATED_EXPORT and SOMELIB_DEPRECATED_NO_EXPORT.
+# The resulting file should be installed with other headers in the library.
+#
+# The BASE_NAME argument can be used to override the file name and the names
+# used for the macros
+#
+#   add_library(somelib someclass.cpp)
+#   generate_export_header(somelib
+#     BASE_NAME other_name
+#   )
+#
+# Generates a file called other_name_export.h containing the macros
+# OTHER_NAME_EXPORT, OTHER_NAME_NO_EXPORT and OTHER_NAME_DEPRECATED etc.
+#
+# The BASE_NAME may be overridden by specifiying other options in the function.
+# For example:
+#
+#   add_library(somelib someclass.cpp)
+#   generate_export_header(somelib
+#     EXPORT_MACRO_NAME OTHER_NAME_EXPORT
+#   )
+#
+# creates the macro OTHER_NAME_EXPORT instead of SOMELIB_EXPORT, but other macros
+# and the generated file name is as default.
+#
+#   add_library(somelib someclass.cpp)
+#   generate_export_header(somelib
+#     DEPRECATED_MACRO_NAME KDE_DEPRECATED
+#   )
+#
+# creates the macro KDE_DEPRECATED instead of SOMELIB_DEPRECATED.
+#
+# If LIBRARY_TARGET is a static library, macros are defined without values.
+#
+# If the same sources are used to create both a shared and a static library, the
+# uppercased symbol ${BASE_NAME}_STATIC_DEFINE should be used when building the
+# static library
+#
+#   add_library(shared_variant SHARED ${lib_SRCS})
+#   add_library(static_variant ${lib_SRCS})
+#   generate_export_header(shared_variant BASE_NAME libshared_and_static)
+#   set_target_properties(static_variant PROPERTIES COMPILE_FLAGS -DLIBSHARED_AND_STATIC_STATIC_DEFINE)
+#
+# This will cause the export macros to expand to nothing when building the static library.
+#
+# If DEFINE_NO_DEPRECATED is specified, then a macro ${BASE_NAME}_NO_DEPRECATED will be defined
+# This macro can be used to remove deprecated code from preprocessor output.
+#
+#   option(EXCLUDE_DEPRECATED "Exclude deprecated parts of the library" FALSE)
+#   if (EXCLUDE_DEPRECATED)
+#     set(NO_BUILD_DEPRECATED DEFINE_NO_DEPRECATED)
+#   endif()
+#   generate_export_header(somelib ${NO_BUILD_DEPRECATED})
+#
+# And then in somelib:
+#
+#   class SOMELIB_EXPORT SomeClass
+#   {
+#   public:
+#   #ifndef SOMELIB_NO_DEPRECATED
+#     SOMELIB_DEPRECATED void oldMethod();
+#   #endif
+#   };
+#
+#   #ifndef SOMELIB_NO_DEPRECATED
+#   void SomeClass::oldMethod() {  }
+#   #endif
+#
+# If PREFIX_NAME is specified, the argument will be used as a prefix to all
+# generated macros.
+#
+# For example:
+#
+#   generate_export_header(somelib PREFIX_NAME VTK_)
+#
+# Generates the macros VTK_SOMELIB_EXPORT etc.
+
+
+#=============================================================================
+# Copyright 2011 Stephen Kelly <steveire@gmail.com>
+#
+# Distributed under the OSI-approved BSD License (the "License");
+# see accompanying file Copyright.txt for details.
+#
+# This software is distributed WITHOUT ANY WARRANTY; without even the
+# implied warranty of MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
+# See the License for more information.
+#=============================================================================
+# (To distribute this file outside of CMake, substitute the full
+#  License text for the above reference.)
+
+include(CMakeParseArguments)
+include(CheckCXXCompilerFlag)
+
+
+# TODO: Install this macro separately?
+macro(_check_cxx_compiler_attribute _ATTRIBUTE _RESULT)
+  check_cxx_source_compiles("${_ATTRIBUTE} int somefunc() { return 0; } int main() { return somefunc();}" ${_RESULT}
+    # Some compilers do not fail with a bad flag
+    FAIL_REGEX "unrecognized .*option"                     # GNU
+    FAIL_REGEX "ignoring unknown option"                   # MSVC
+    FAIL_REGEX "warning D9002"                             # MSVC, any lang
+    FAIL_REGEX "[Uu]nknown option"                         # HP
+    FAIL_REGEX "[Ww]arning: [Oo]ption"                     # SunPro
+    FAIL_REGEX "command option .* is not recognized"       # XL
+  )
+endmacro()
+
+macro(_test_compiler_hidden_visibility)
+
+  if (CMAKE_COMPILER_IS_GNUCXX)
+    exec_program(${CMAKE_C_COMPILER} ARGS --version OUTPUT_VARIABLE     _gcc_version_info)
+    string (REGEX MATCH "[345]\\.[0-9]\\.[0-9]" _gcc_version "${_gcc_version_info}")
+    # gcc on mac just reports: "gcc (GCC) 3.3 20030304 ..." without the
+    # patch level, handle this here:
+    if(NOT _gcc_version)
+      string (REGEX REPLACE ".*\\(GCC\\).* ([34]\\.[0-9]) .*" "\\1.0" _gcc_version "${_gcc_version_info}")
+    endif()
+
+    if(${_gcc_version} VERSION_LESS "4.2")
+      set(GCC_TOO_OLD TRUE)
+      message(WARNING "GCC version older than 4.2")
+    endif()
+  endif()
+
+  if(CMAKE_CXX_COMPILER_ID MATCHES Intel)
+    exec_program(${CMAKE_CXX_COMPILER} ARGS -V OUTPUT_VARIABLE     _intel_version_info)
+    string (REGEX REPLACE ".*Version ([0-9]+(\\.[0-9]+)+).*" "\\1" _intel_version "${_intel_version_info}")
+
+    if(${_intel_version} VERSION_LESS "12.0")
+      set(_INTEL_TOO_OLD TRUE)
+      message(WARNING "Intel compiler older than 12.0")
+    endif()
+  endif()
+
+
+  # Exclude XL here because it misinterprets -fvisibility=hidden even though
+  # the check_cxx_compiler_flag passes
+  # http://www.cdash.org/CDash/testDetails.php?test=109109951&build=1419259
+  if (NOT GCC_TOO_OLD
+      AND NOT _INTEL_TOO_OLD
+      AND NOT WIN32
+      AND NOT CYGWIN
+      AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES XL
+      AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES PGI
+      AND NOT "${CMAKE_CXX_COMPILER_ID}" MATCHES Watcom)
+    check_cxx_compiler_flag(-fvisibility=hidden COMPILER_HAS_HIDDEN_VISIBILITY)
+    check_cxx_compiler_flag(-fvisibility-inlines-hidden COMPILER_HAS_HIDDEN_INLINE_VISIBILITY)
+    option(USE_COMPILER_HIDDEN_VISIBILITY "Use HIDDEN visibility support if available." ON)
+    mark_as_advanced(USE_COMPILER_HIDDEN_VISIBILITY)
+  endif()
+endmacro()
+
+macro(_test_compiler_has_deprecated)
+  if("${CMAKE_CXX_COMPILER_ID}" MATCHES Borland
+      OR "${CMAKE_CXX_COMPILER_ID}" MATCHES HP
+      OR GCC_TOO_OLD
+      OR "${CMAKE_CXX_COMPILER_ID}" MATCHES PGI
+      OR "${CMAKE_CXX_COMPILER_ID}" MATCHES Watcom)
+    set(COMPILER_HAS_DEPRECATED "" CACHE INTERNAL "Compiler support for a deprecated attribute")
+  else()
+    _check_cxx_compiler_attribute("__attribute__((__deprecated__))" COMPILER_HAS_DEPRECATED_ATTR)
+    if(COMPILER_HAS_DEPRECATED_ATTR)
+      set(COMPILER_HAS_DEPRECATED "${COMPILER_HAS_DEPRECATED_ATTR}" CACHE INTERNAL "Compiler support for a deprecated attribute")
+    else()
+      _check_cxx_compiler_attribute("__declspec(deprecated)" COMPILER_HAS_DEPRECATED)
+    endif()
+  endif()
+endmacro()
+
+get_filename_component(_GENERATE_EXPORT_HEADER_MODULE_DIR "${CMAKE_CURRENT_LIST_FILE}" PATH)
+
+macro(_DO_SET_MACRO_VALUES TARGET_LIBRARY)
+  set(DEFINE_DEPRECATED)
+  set(DEFINE_EXPORT)
+  set(DEFINE_IMPORT)
+  set(DEFINE_NO_EXPORT)
+
+  if (COMPILER_HAS_DEPRECATED_ATTR)
+    set(DEFINE_DEPRECATED "__attribute__ ((__deprecated__))")
+  elseif(COMPILER_HAS_DEPRECATED)
+    set(DEFINE_DEPRECATED "__declspec(deprecated)")
+  endif()
+
+  get_property(type TARGET ${TARGET_LIBRARY} PROPERTY TYPE)
+
+  if(NOT ${type} STREQUAL "STATIC_LIBRARY")
+    if(WIN32)
+      set(DEFINE_EXPORT "__declspec(dllexport)")
+      set(DEFINE_IMPORT "__declspec(dllimport)")
+    elseif(COMPILER_HAS_HIDDEN_VISIBILITY AND USE_COMPILER_HIDDEN_VISIBILITY)
+      set(DEFINE_EXPORT "__attribute__((visibility(\"default\")))")
+      set(DEFINE_IMPORT "__attribute__((visibility(\"default\")))")
+      set(DEFINE_NO_EXPORT "__attribute__((visibility(\"hidden\")))")
+    endif()
+  endif()
+endmacro()
+
+macro(_DO_GENERATE_EXPORT_HEADER TARGET_LIBRARY)
+  # Option overrides
+  set(options DEFINE_NO_DEPRECATED)
+  set(oneValueArgs PREFIX_NAME BASE_NAME EXPORT_MACRO_NAME EXPORT_FILE_NAME DEPRECATED_MACRO_NAME NO_EXPORT_MACRO_NAME STATIC_DEFINE NO_DEPRECATED_MACRO_NAME)
+  set(multiValueArgs)
+
+  cmake_parse_arguments(_GEH "${options}" "${oneValueArgs}" "${multiValueArgs}" ${ARGN})
+
+  set(BASE_NAME "${TARGET_LIBRARY}")
+
+  if(_GEH_BASE_NAME)
+    set(BASE_NAME ${_GEH_BASE_NAME})
+  endif()
+
+  string(TOUPPER ${BASE_NAME} BASE_NAME_UPPER)
+  string(TOLOWER ${BASE_NAME} BASE_NAME_LOWER)
+
+  # Default options
+  set(EXPORT_MACRO_NAME "${_GEH_PREFIX_NAME}${BASE_NAME_UPPER}_EXPORT")
+  set(NO_EXPORT_MACRO_NAME "${_GEH_PREFIX_NAME}${BASE_NAME_UPPER}_NO_EXPORT")
+  set(EXPORT_FILE_NAME "${CMAKE_CURRENT_BINARY_DIR}/${BASE_NAME_LOWER}_export.h")
+  set(DEPRECATED_MACRO_NAME "${_GEH_PREFIX_NAME}${BASE_NAME_UPPER}_DEPRECATED")
+  set(STATIC_DEFINE "${_GEH_PREFIX_NAME}${BASE_NAME_UPPER}_STATIC_DEFINE")
+  set(NO_DEPRECATED_MACRO_NAME "${_GEH_PREFIX_NAME}${BASE_NAME_UPPER}_NO_DEPRECATED")
+
+  if(_GEH_UNPARSED_ARGUMENTS)
+    message(FATAL_ERROR "Unknown keywords given to GENERATE_EXPORT_HEADER(): \"${_GEH_UNPARSED_ARGUMENTS}\"")
+  endif()
+
+  if(_GEH_EXPORT_MACRO_NAME)
+    set(EXPORT_MACRO_NAME ${_GEH_PREFIX_NAME}${_GEH_EXPORT_MACRO_NAME})
+  endif()
+  if(_GEH_EXPORT_FILE_NAME)
+    if(IS_ABSOLUTE _GEH_EXPORT_FILE_NAME)
+      set(EXPORT_FILE_NAME ${_GEH_EXPORT_FILE_NAME})
+    else()
+      set(EXPORT_FILE_NAME "${CMAKE_CURRENT_BINARY_DIR}/${_GEH_EXPORT_FILE_NAME}")
+    endif()
+  endif()
+  if(_GEH_DEPRECATED_MACRO_NAME)
+    set(DEPRECATED_MACRO_NAME ${_GEH_PREFIX_NAME}${_GEH_DEPRECATED_MACRO_NAME})
+  endif()
+  if(_GEH_NO_EXPORT_MACRO_NAME)
+    set(NO_EXPORT_MACRO_NAME ${_GEH_PREFIX_NAME}${_GEH_NO_EXPORT_MACRO_NAME})
+  endif()
+  if(_GEH_STATIC_DEFINE)
+    set(STATIC_DEFINE ${_GEH_PREFIX_NAME}${_GEH_STATIC_DEFINE})
+  endif()
+
+  if (_GEH_DEFINE_NO_DEPRECATED)
+    set(DEFINE_NO_DEPRECATED TRUE)
+  endif()
+
+  if (_GEH_NO_DEPRECATED_MACRO_NAME)
+    set(NO_DEPRECATED_MACRO_NAME ${_GEH_PREFIX_NAME}${_GEH_NO_DEPRECATED_MACRO_NAME})
+  endif()
+
+  set(INCLUDE_GUARD_NAME "${EXPORT_MACRO_NAME}_H")
+
+  get_target_property(EXPORT_IMPORT_CONDITION ${TARGET_LIBRARY} DEFINE_SYMBOL)
+
+  if (NOT EXPORT_IMPORT_CONDITION)
+    set(EXPORT_IMPORT_CONDITION ${TARGET_LIBRARY}_EXPORTS)
+  endif()
+
+  configure_file("${_GENERATE_EXPORT_HEADER_MODULE_DIR}/exportheader.cmake.in" "${EXPORT_FILE_NAME}" @ONLY)
+endmacro()
+
+function(GENERATE_EXPORT_HEADER TARGET_LIBRARY)
+  get_property(type TARGET ${TARGET_LIBRARY} PROPERTY TYPE)
+  if(${type} STREQUAL "MODULE")
+    message(WARNING "This macro should not be used with libraries of type MODULE")
+    return()
+  endif()
+  if(NOT ${type} STREQUAL "STATIC_LIBRARY" AND NOT ${type} STREQUAL "SHARED_LIBRARY")
+    message(WARNING "This macro can only be used with libraries")
+    return()
+  endif()
+  _test_compiler_hidden_visibility()
+  _test_compiler_has_deprecated()
+  _do_set_macro_values(${TARGET_LIBRARY})
+  _do_generate_export_header(${TARGET_LIBRARY} ${ARGN})
+endfunction()
+
+function(add_compiler_export_flags)
+
+  _test_compiler_hidden_visibility()
+  _test_compiler_has_deprecated()
+
+  if(NOT (USE_COMPILER_HIDDEN_VISIBILITY AND COMPILER_HAS_HIDDEN_VISIBILITY))
+    message(WARNING "Compiler doesn't have hidden visibility")
+    return()
+  endif()
+
+  set (EXTRA_FLAGS "-fvisibility=hidden")
+
+  if(COMPILER_HAS_HIDDEN_INLINE_VISIBILITY)
+    set (EXTRA_FLAGS "${EXTRA_FLAGS} -fvisibility-inlines-hidden")
+  endif()
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${EXTRA_FLAGS}" PARENT_SCOPE)
+endfunction()
--- a/Modules/exportheader.cmake.in
+++ b/Modules/exportheader.cmake.in
@ -0,0 +1,35 @@
+
+#ifndef @INCLUDE_GUARD_NAME@
+#define @INCLUDE_GUARD_NAME@
+
+#ifdef @STATIC_DEFINE@
+#  define @EXPORT_MACRO_NAME@
+#  define @NO_EXPORT_MACRO_NAME@
+#else
+#  ifndef @EXPORT_MACRO_NAME@
+#    ifdef @EXPORT_IMPORT_CONDITION@
+        /* We are building this library */
+#      define @EXPORT_MACRO_NAME@ @DEFINE_EXPORT@
+#    else
+        /* We are using this library */
+#      define @EXPORT_MACRO_NAME@ @DEFINE_IMPORT@
+#    endif
+#  endif
+
+#  ifndef @NO_EXPORT_MACRO_NAME@
+#    define @NO_EXPORT_MACRO_NAME@ @DEFINE_NO_EXPORT@
+#  endif
+#endif
+
+#ifndef @DEPRECATED_MACRO_NAME@
+#  define @DEPRECATED_MACRO_NAME@ @DEFINE_DEPRECATED@
+#  define @DEPRECATED_MACRO_NAME@_EXPORT @EXPORT_MACRO_NAME@ @DEFINE_DEPRECATED@
+#  define @DEPRECATED_MACRO_NAME@_NO_EXPORT @NO_EXPORT_MACRO_NAME@ @DEFINE_DEPRECATED@
+#endif
+
+#cmakedefine01 DEFINE_NO_DEPRECATED
+#if DEFINE_NO_DEPRECATED
+# define @NO_DEPRECATED_MACRO_NAME@
+#endif
+
+#endif // @INCLUDE_GUARD_NAME@
--- a/Tests/CMakeLists.txt
+++ b/Tests/CMakeLists.txt
@ -228,6 +228,10 @@ IF(BUILD_TESTING)

  ADD_TEST_MACRO(Module.CheckTypeSize CheckTypeSize)

+  ADD_TEST_MACRO(Module.GenerateExportHeader GenerateExportHeader)
+
+  ADD_TEST_MACRO(Module.CheckCXXCompilerFlag CheckCXXCompilerFlag)
+
  ADD_TEST(LinkFlags-prepare
    ${CMAKE_CTEST_COMMAND} -C \${CTEST_CONFIGURATION_TYPE}
    --build-and-test
--- a/Tests/Module/CheckCXXCompilerFlag/CMakeLists.txt
+++ b/Tests/Module/CheckCXXCompilerFlag/CMakeLists.txt
@ -0,0 +1,74 @@
+cmake_minimum_required(VERSION 2.8)
+project(CheckCXXCompilerFlag)
+
+message(STATUS "CTEST_FULL_OUTPUT (Avoid ctest truncation of output)")
+set(CMAKE_VERBOSE_MAKEFILE 1)
+
+macro(TEST_FAIL value msg)
+  if (${value})
+    message (SEND_ERROR "Test fail:" ${msg} ${Out} )
+  endif ()
+endmacro()
+
+macro(TEST_PASS value msg)
+  if (NOT ${value})
+    message (SEND_ERROR "Test fail:" ${msg} ${Out} )
+  endif ()
+endmacro()
+
+if(CMAKE_COMPILER_IS_GNUCXX)
+  exec_program(${CMAKE_C_COMPILER} ARGS --version OUTPUT_VARIABLE     _gcc_version_info)
+  string (REGEX MATCH "[345]\\.[0-9]\\.[0-9]" _gcc_version "${_gcc_version_info}")
+  # gcc on mac just reports: "gcc (GCC) 3.3 20030304 ..." without the
+  # patch level, handle this here:
+  if(NOT _gcc_version)
+    string (REGEX REPLACE ".*\\(GCC\\).* ([34]\\.[0-9]) .*" "\\1.0" _gcc_version "${_gcc_version_info}")
+  endif()
+endif()
+
+if(CMAKE_CXX_COMPILER_ID MATCHES Clang)
+  exec_program(${CMAKE_CXX_COMPILER} ARGS --version OUTPUT_VARIABLE     _clang_version_info)
+  string (REGEX REPLACE ".*version ([0-9]\\.[0-9]).*" "\\1" _clang_version "${_clang_version_info}")
+endif()
+
+if(CMAKE_CXX_COMPILER_ID MATCHES Intel)
+  exec_program(${CMAKE_CXX_COMPILER} ARGS -V OUTPUT_VARIABLE     _intel_version_info)
+  string (REGEX REPLACE ".*Version ([0-9]+(\\.[0-9]+)+).*" "\\1" _intel_version "${_intel_version_info}")
+endif()
+
+message("Platform:\n  WIN32: ${WIN32}\n  UNIX: ${UNIX}\n  APPLE: ${APPLE}\n  MINGW: ${MINGW}\n  CYGWIN: ${CYGWIN}\n"
+  "  MSVC: ${MSVC}\n  MSVC60: ${MSVC60}\n  MSVC70: ${MSVC70}\n  MSVC71: ${MSVC71}\n  MSVC80: ${MSVC80}\n  MSVC90: ${MSVC90}\n  MSVC10: ${MSVC10}\n"
+  "  GCC: ${_gcc_version}\n"
+  "  Clang: ${_clang_version}\n"
+  "  Intel: ${_intel_version}\n"
+)
+
+include(CheckCXXCompilerFlag)
+
+check_cxx_compiler_flag(-fvisibility=hidden HAS_HIDDEN_VISIBILITY)
+
+message("HAS_HIDDEN_VISIBILITY: ${HAS_HIDDEN_VISIBILITY}\n\nCOMPILE OUTPUT:\n${OUTPUT}")
+
+if(CMAKE_COMPILER_IS_GNUCXX)
+  if(NOT WIN32)
+#     test_pass(HAS_HIDDEN_VISIBILITY "GCC should support hidden visibility, but does not.")
+  endif()
+else()
+  message("Unhandled Platform")
+endif()
+
+#
+# This is a no-op executable... If this test is going to fail, it fails during
+# the configure step while cmake is configuring this CMakeLists.txt file...
+#
+
+file(WRITE
+  "${CMAKE_CURRENT_BINARY_DIR}/main.cxx"
+  "int main() { return 0; }
+"
+)
+
+add_executable(
+  CheckCXXCompilerFlag
+  "${CMAKE_CURRENT_BINARY_DIR}/main.cxx"
+)
--- a/Tests/Module/GenerateExportHeader/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/CMakeLists.txt
@ -0,0 +1,168 @@
+cmake_minimum_required(VERSION 2.8.5 FATAL_ERROR)
+
+project(GenerateExportHeader)
+
+# Prevent timeout on Watcom by not running the tests.
+if ("${CMAKE_CXX_COMPILER_ID}" MATCHES Watcom)
+  file(WRITE
+    "${CMAKE_CURRENT_BINARY_DIR}/main.cxx"
+    "int main() { return 0; }
+  "
+  )
+
+  add_executable(
+    GenerateExportHeader
+    "${CMAKE_CURRENT_BINARY_DIR}/main.cxx"
+  )
+  return()
+endif()
+
+include(CheckCXXCompilerFlag)
+
+set( CMAKE_INCLUDE_CURRENT_DIR ON )
+
+macro(TEST_FAIL value msg)
+  if (${value})
+    message (SEND_ERROR "Test fail:" ${msg} ${Out} )
+  endif ()
+endmacro()
+
+macro(TEST_PASS value msg)
+  if (NOT ${value})
+    message (SEND_ERROR "Test fail:" ${msg} ${Out} )
+  endif ()
+endmacro()
+
+check_cxx_compiler_flag(-Werror HAS_WERROR_FLAG)
+
+if(HAS_WERROR_FLAG)
+  set(ERROR_FLAG "-Werror")
+else()
+  # MSVC
+  # And intel on windows?
+  # http://software.intel.com/en-us/articles/how-to-handle-warnings-message-in-compiler/?wapkw=%28compiler+warning+message%29
+  check_cxx_compiler_flag("/WX" HAS_WX_FLAG)
+  if(HAS_WX_FLAG)
+    set(ERROR_FLAG "/WX")
+  else()
+    # Sun CC
+    # http://www.acsu.buffalo.edu/~charngda/sunstudio.html
+    check_cxx_compiler_flag("-errwarn=%all" HAS_ERRWARN_ALL)
+    if (HAS_ERRWARN_ALL)
+      set(ERROR_FLAG "-errwarn=%all")
+    else()
+    endif()
+  endif()
+endif()
+
+
+# We seem to get race conditions is writing this stuff to the same file at least on MinGW
+# So to write to separate source and build directories, we use a count to differentiate.
+set (COUNT 0)
+macro(_do_build Include Library LibrarySource Source)
+
+  math(EXPR COUNT "${COUNT} + 1" )
+
+  file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/test${COUNT}/src.cpp" "#include \"${Include}\"\n"
+    "int main() { ${Source}; }\n"
+  )
+
+  file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/../${LibrarySource}" DESTINATION "${CMAKE_CURRENT_BINARY_DIR}/test${COUNT}")
+
+  if ("${Library}" STREQUAL "static_variant")
+    set(CONDITIONAL_STATIC_DEFINE "add_definitions(-DLIBSHARED_AND_STATIC_STATIC_DEFINE)\n")
+  endif()
+
+  file(WRITE "${CMAKE_CURRENT_BINARY_DIR}/test${COUNT}/CMakeLists.txt"
+    "cmake_minimum_required(VERSION 2.8)\n"
+
+    "project(compiletest)\n"
+
+    "set(CMAKE_INCLUDE_CURRENT_DIR ON)\n"
+
+    "set(CMAKE_RUNTIME_OUTPUT_DIRECTORY \"\${CMAKE_CURRENT_BINARY_DIR}\")\n"
+
+    "include(GenerateExportHeader)\n"
+
+    "add_compiler_export_flags()\n"
+
+    "if(NOT \"${ERROR_FLAG}\" STREQUAL \"\")\n"
+    "  add_definitions(${ERROR_FLAG})\n"
+    "endif()\n"
+
+    "if(MSVC)\n"
+    "  add_definitions(-DCOMPILER_IS_MSVC)\n"
+    "endif()\n"
+
+    "add_subdirectory(\"${LibrarySource}\")\n"
+
+    "include_directories(\"${LibrarySource}\" \"\${CMAKE_CURRENT_BINARY_DIR}/${LibrarySource}\")\n"
+
+    "${CONDITIONAL_STATIC_DEFINE}"
+
+    "add_executable(compiletest src.cpp)\n"
+    "target_link_libraries(compiletest ${Library})\n"
+  )
+
+  try_compile(Result ${CMAKE_CURRENT_BINARY_DIR}/fail${COUNT}
+    ${CMAKE_CURRENT_BINARY_DIR}/test${COUNT}
+    compiletest
+    OUTPUT_VARIABLE Out
+  )
+endmacro()
+
+macro(build_fail Include Library LibrarySource Source Message)
+  _do_build(${Include} ${Library} ${LibrarySource} "${Source}")
+  test_fail(Result ${Message})
+endmacro()
+
+macro(build_pass Include Library LibrarySource Source Message)
+  _do_build(${Include} ${Library} ${LibrarySource} "${Source}")
+  test_pass(Result ${Message})
+endmacro()
+
+include(GenerateExportHeader)
+
+add_compiler_export_flags()
+
+if (MSVC)
+  add_definitions(-DCOMPILER_IS_MSVC)
+endif()
+
+set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_CURRENT_BINARY_DIR})
+
+message("#### COMPILER_HAS_DEPRECATED: " ${COMPILER_HAS_DEPRECATED})
+message("#### COMPILER_HAS_HIDDEN_VISIBILITY: " ${COMPILER_HAS_HIDDEN_VISIBILITY})
+message("#### WIN32: " ${WIN32})
+message("#### HAS_WERROR_FLAG: " ${HAS_WERROR_FLAG})
+
+set(link_libraries)
+macro(macro_add_test_library name)
+  add_subdirectory(${name})
+  include_directories(${name}
+            ${${name}_BINARY_DIR} # For the export header.
+  )
+  list(APPEND link_libraries ${name})
+  add_subdirectory(${name}test)
+endmacro()
+
+macro_add_test_library(libshared)
+macro_add_test_library(libstatic)
+add_subdirectory(lib_shared_and_static)
+add_subdirectory(lib_shared_and_statictest)
+
+add_subdirectory(override_symbol)
+
+if (CMAKE_COMPILER_IS_GNUCXX OR (${CMAKE_CXX_COMPILER_ID} MATCHES Clang))
+  # We deliberately call deprecated methods, and test for that elsewhere.
+  # No need to clutter the test output with warnings.
+  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wno-deprecated-declarations")
+endif()
+
+if(MSVC AND COMPILER_HAS_DEPRECATED)
+  add_definitions(/wd4996)
+endif()
+
+add_executable(GenerateExportHeader exportheader_test.cpp)
+
+target_link_libraries(GenerateExportHeader ${link_libraries})
--- a/Tests/Module/GenerateExportHeader/exportheader_test.cpp
+++ b/Tests/Module/GenerateExportHeader/exportheader_test.cpp
@ -0,0 +1,82 @@
+
+#include "libshared.h"
+
+#include "libstatic.h"
+
+// #define BUILD_FAIL
+
+#ifndef BUILD_FAIL
+#define DOES_NOT_BUILD(function)
+#else
+#define DOES_NOT_BUILD(function) function
+#endif
+
+int main()
+{
+  {
+    Libshared l;
+    l.libshared();
+    l.libshared_exported();
+    l.libshared_deprecated();
+    l.libshared_not_exported();
+
+    DOES_NOT_BUILD(l.libshared_excluded();)
+  }
+
+  {
+    LibsharedNotExported l;
+    DOES_NOT_BUILD(l.libshared();)
+    l.libshared_exported();
+    l.libshared_deprecated();
+    DOES_NOT_BUILD(l.libshared_not_exported();)
+    DOES_NOT_BUILD(l.libshared_excluded();)
+  }
+
+  {
+    LibsharedExcluded l;
+    DOES_NOT_BUILD(l.libshared();)
+    l.libshared_exported();
+    l.libshared_deprecated();
+    DOES_NOT_BUILD(l.libshared_not_exported();)
+    DOES_NOT_BUILD(l.libshared_excluded();)
+  }
+
+  libshared_exported();
+  libshared_deprecated();
+  DOES_NOT_BUILD(libshared_not_exported();)
+  DOES_NOT_BUILD(libshared_excluded();)
+
+  {
+    Libstatic l;
+    l.libstatic();
+    l.libstatic_exported();
+    l.libstatic_deprecated();
+    l.libstatic_not_exported();
+    l.libstatic_excluded();
+  }
+
+  {
+    LibstaticNotExported l;
+    l.libstatic();
+    l.libstatic_exported();
+    l.libstatic_deprecated();
+    l.libstatic_not_exported();
+    l.libstatic_excluded();
+  }
+
+  {
+    LibstaticExcluded l;
+    l.libstatic();
+    l.libstatic_exported();
+    l.libstatic_deprecated();
+    l.libstatic_not_exported();
+    l.libstatic_excluded();
+  }
+
+  libstatic_exported();
+  libstatic_deprecated();
+  libstatic_not_exported();
+  libstatic_excluded();
+
+  return 0;
+}
--- a/Tests/Module/GenerateExportHeader/lib_shared_and_static/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/lib_shared_and_static/CMakeLists.txt
@ -0,0 +1,12 @@
+project(shared_and_static)
+
+set(lib_SRCS
+  libshared_and_static.cpp
+)
+
+add_library(shared_variant SHARED ${lib_SRCS})
+add_library(static_variant ${lib_SRCS})
+
+generate_export_header(shared_variant BASE_NAME libshared_and_static)
+
+set_target_properties(static_variant PROPERTIES COMPILE_FLAGS -DLIBSHARED_AND_STATIC_STATIC_DEFINE)
--- a/Tests/Module/GenerateExportHeader/lib_shared_and_static/libshared_and_static.cpp
+++ b/Tests/Module/GenerateExportHeader/lib_shared_and_static/libshared_and_static.cpp
@ -0,0 +1,91 @@
+
+#include "libshared_and_static.h"
+
+int LibsharedAndStatic::libshared_and_static() const
+{
+  return 0;
+}
+
+int LibsharedAndStatic::libshared_and_static_exported() const
+{
+  return 0;
+}
+
+int LibsharedAndStatic::libshared_and_static_deprecated() const
+{
+  return 0;
+}
+
+int LibsharedAndStatic::libshared_and_static_not_exported() const {
+  return 0;
+}
+
+int LibsharedAndStatic::libshared_and_static_excluded() const {
+  return 0;
+}
+
+int LibsharedAndStaticNotExported::libshared_and_static() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticNotExported::libshared_and_static_exported() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticNotExported::libshared_and_static_deprecated() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticNotExported::libshared_and_static_not_exported() const {
+  return 0;
+}
+
+int LibsharedAndStaticNotExported::libshared_and_static_excluded() const {
+  return 0;
+}
+
+int LibsharedAndStaticExcluded::libshared_and_static() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticExcluded::libshared_and_static_exported() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticExcluded::libshared_and_static_deprecated() const
+{
+  return 0;
+}
+
+int LibsharedAndStaticExcluded::libshared_and_static_not_exported() const {
+  return 0;
+}
+
+int LibsharedAndStaticExcluded::libshared_and_static_excluded() const {
+  return 0;
+}
+
+int libshared_and_static() {
+  return 0;
+}
+
+int libshared_and_static_exported() {
+  return 0;
+}
+
+int libshared_and_static_deprecated() {
+  return 0;
+}
+
+int libshared_and_static_not_exported() {
+  return 0;
+}
+
+int libshared_and_static_excluded() {
+  return 0;
+}
--- a/Tests/Module/GenerateExportHeader/lib_shared_and_static/libshared_and_static.h
+++ b/Tests/Module/GenerateExportHeader/lib_shared_and_static/libshared_and_static.h
@ -0,0 +1,54 @@
+
+#ifndef SHARED_AND_STATIC_H
+#define SHARED_AND_STATIC_H
+
+#include "libshared_and_static_export.h"
+
+class LIBSHARED_AND_STATIC_EXPORT LibsharedAndStatic {
+public:
+  int libshared_and_static() const;
+
+  int libshared_and_static_exported() const;
+
+  int LIBSHARED_AND_STATIC_DEPRECATED libshared_and_static_deprecated() const;
+
+  int libshared_and_static_not_exported() const;
+
+  int LIBSHARED_AND_STATIC_NO_EXPORT libshared_and_static_excluded() const;
+};
+
+class LibsharedAndStaticNotExported {
+public:
+  int libshared_and_static() const;
+
+  int LIBSHARED_AND_STATIC_EXPORT libshared_and_static_exported() const;
+
+  int LIBSHARED_AND_STATIC_DEPRECATED libshared_and_static_deprecated() const;
+
+  int libshared_and_static_not_exported() const;
+
+  int LIBSHARED_AND_STATIC_NO_EXPORT libshared_and_static_excluded() const;
+};
+
+class LIBSHARED_AND_STATIC_NO_EXPORT LibsharedAndStaticExcluded {
+public:
+  int libshared_and_static() const;
+
+  int LIBSHARED_AND_STATIC_EXPORT libshared_and_static_exported() const;
+
+  int LIBSHARED_AND_STATIC_DEPRECATED libshared_and_static_deprecated() const;
+
+  int libshared_and_static_not_exported() const;
+
+  int LIBSHARED_AND_STATIC_NO_EXPORT libshared_and_static_excluded() const;
+};
+
+LIBSHARED_AND_STATIC_EXPORT int libshared_and_static_exported();
+
+LIBSHARED_AND_STATIC_DEPRECATED_EXPORT int libshared_and_static_deprecated();
+
+int libshared_and_static_not_exported();
+
+int LIBSHARED_AND_STATIC_NO_EXPORT libshared_and_static_excluded();
+
+#endif
--- a/Tests/Module/GenerateExportHeader/lib_shared_and_statictest/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/lib_shared_and_statictest/CMakeLists.txt
@ -0,0 +1,33 @@
+
+macro(shared_variant_build_pass Source Message)
+  build_pass("libshared_and_static.h" "shared_variant" "lib_shared_and_static" "${Source}" ${Message})
+endmacro()
+
+macro(shared_variant_build_fail Source Message)
+  build_fail("libshared_and_static.h" "shared_variant" "lib_shared_and_static" "${Source}" ${Message})
+endmacro()
+
+macro(static_variant_build_pass Source Message)
+  build_pass("libshared_and_static.h" "static_variant" "lib_shared_and_static" "${Source}" ${Message})
+endmacro()
+
+macro(static_variant_build_fail Source Message)
+  build_fail("libshared_and_static.h" "static_variant" "lib_shared_and_static" "${Source}" ${Message})
+endmacro()
+
+static_variant_build_pass("return libshared_and_static_exported();" "Failed to build static variant")
+shared_variant_build_pass("return libshared_and_static_exported();" "Failed to build shared variant")
+# if (COMPILER_HAS_DEPRECATED)
+#   shared_variant_build_fail("return libshared_and_static_deprecated();" "Built shared deprecated variant")
+#   static_variant_build_fail("return libshared_and_static_deprecated();" "Built static deprecated variant")
+# else()
+#   shared_variant_build_pass("return libshared_and_static_deprecated();" "Built shared deprecated variant")
+#   static_variant_build_pass("return libshared_and_static_deprecated();" "Built static deprecated variant")
+# endif()
+static_variant_build_pass("return libshared_and_static_not_exported();" "Failed to build static not exported variant")
+
+if (WIN32 OR COMPILER_HAS_HIDDEN_VISIBILITY)
+  shared_variant_build_fail("return libshared_and_static_not_exported();" "Built shared not exported variant")
+else()
+  shared_variant_build_pass("return libshared_and_static_not_exported();" "Built shared not exported variant")
+endif()
--- a/Tests/Module/GenerateExportHeader/libshared/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/libshared/CMakeLists.txt
@ -0,0 +1,6 @@
+
+project(libshared)
+
+add_library(libshared SHARED libshared.cpp)
+
+generate_export_header(libshared)
--- a/Tests/Module/GenerateExportHeader/libshared/libshared.cpp
+++ b/Tests/Module/GenerateExportHeader/libshared/libshared.cpp
@ -0,0 +1,91 @@
+
+#include "libshared.h"
+
+int Libshared::libshared() const
+{
+  return 0;
+}
+
+int Libshared::libshared_exported() const
+{
+  return 0;
+}
+
+int Libshared::libshared_deprecated() const
+{
+  return 0;
+}
+
+int Libshared::libshared_not_exported() const {
+  return 0;
+}
+
+int Libshared::libshared_excluded() const {
+  return 0;
+}
+
+int LibsharedNotExported::libshared() const
+{
+  return 0;
+}
+
+int LibsharedNotExported::libshared_exported() const
+{
+  return 0;
+}
+
+int LibsharedNotExported::libshared_deprecated() const
+{
+  return 0;
+}
+
+int LibsharedNotExported::libshared_not_exported() const {
+  return 0;
+}
+
+int LibsharedNotExported::libshared_excluded() const {
+  return 0;
+}
+
+int LibsharedExcluded::libshared() const
+{
+  return 0;
+}
+
+int LibsharedExcluded::libshared_exported() const
+{
+  return 0;
+}
+
+int LibsharedExcluded::libshared_deprecated() const
+{
+  return 0;
+}
+
+int LibsharedExcluded::libshared_not_exported() const {
+  return 0;
+}
+
+int LibsharedExcluded::libshared_excluded() const {
+  return 0;
+}
+
+int libshared() {
+  return 0;
+}
+
+int libshared_exported() {
+  return 0;
+}
+
+int libshared_deprecated() {
+  return 0;
+}
+
+int libshared_not_exported() {
+  return 0;
+}
+
+int libshared_excluded() {
+  return 0;
+}
--- a/Tests/Module/GenerateExportHeader/libshared/libshared.h
+++ b/Tests/Module/GenerateExportHeader/libshared/libshared.h
@ -0,0 +1,54 @@
+
+#ifndef LIBSHARED_H
+#define LIBSHARED_H
+
+#include "libshared_export.h"
+
+class LIBSHARED_EXPORT Libshared {
+public:
+  int libshared() const;
+
+  int libshared_exported() const;
+
+  int LIBSHARED_DEPRECATED libshared_deprecated() const;
+
+  int libshared_not_exported() const;
+
+  int LIBSHARED_NO_EXPORT libshared_excluded() const;
+};
+
+class LibsharedNotExported {
+public:
+  int libshared() const;
+
+  int LIBSHARED_EXPORT libshared_exported() const;
+
+  int LIBSHARED_DEPRECATED_EXPORT libshared_deprecated() const;
+
+  int libshared_not_exported() const;
+
+  int LIBSHARED_NO_EXPORT libshared_excluded() const;
+};
+
+class LIBSHARED_NO_EXPORT LibsharedExcluded {
+public:
+  int libshared() const;
+
+  int LIBSHARED_EXPORT libshared_exported() const;
+
+  int LIBSHARED_DEPRECATED_EXPORT libshared_deprecated() const;
+
+  int libshared_not_exported() const;
+
+  int LIBSHARED_NO_EXPORT libshared_excluded() const;
+};
+
+LIBSHARED_EXPORT int libshared_exported();
+
+LIBSHARED_DEPRECATED_EXPORT int libshared_deprecated();
+
+int libshared_not_exported();
+
+int LIBSHARED_NO_EXPORT libshared_excluded();
+
+#endif
--- a/Tests/Module/GenerateExportHeader/libsharedtest/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/libsharedtest/CMakeLists.txt
@ -0,0 +1,44 @@
+
+macro(shared_build_pass Source Message)
+    build_pass("libshared.h" "libshared" "libshared" "${Source}" ${Message})
+endmacro()
+
+macro(shared_build_fail Source Message)
+    build_fail("libshared.h" "libshared" "libshared" "${Source}" ${Message})
+endmacro()
+
+shared_build_pass("Libshared l; return l.libshared_exported();" "Failed to build exported")
+
+# if (COMPILER_HAS_DEPRECATED)
+#   shared_build_fail("Libshared l; return l.libshared_deprecated();" "Built use of deprecated class method. This should not be possible.")
+# else()
+#   shared_build_pass("Libshared l; return l.libshared_deprecated();" "Built use of deprecated class method. This should not be possible.")
+# endif()
+if (COMPILER_HAS_HIDDEN_VISIBILITY)
+  shared_build_fail("Libshared l; return l.libshared_excluded();" "Built use of excluded class method. This should not be possible.")
+else()
+  # There is no MSVC equivalent to hiding symbols.
+  shared_build_pass("Libshared l; return l.libshared_excluded();" "Built use of excluded class method. This is possible on MSVC.")
+endif()
+
+if (WIN32 OR COMPILER_HAS_HIDDEN_VISIBILITY)
+  shared_build_fail("LibsharedNotExported l; return l.libshared();" "Built use of not-exported class method. This should not be possible.")
+  shared_build_fail("LibsharedNotExported l; return l.libshared_not_exported();" "Built use of not-exported class method. This should not be possible.")
+  shared_build_fail("LibsharedNotExported l; return l.libshared_excluded();" "Built use of not-exported class method. This should not be possible.")
+  shared_build_fail("LibsharedExcluded l; return l.libshared();" "Built use of excluded class method. This should not be possible.")
+  shared_build_fail("LibsharedExcluded l; return l.libshared_not_exported();" "Built use of excluded class method. This should not be possible.")
+  shared_build_fail("LibsharedExcluded l; return l.libshared_excluded();" "Built use of excluded class method. This should not be possible.")
+
+  shared_build_fail("return libshared_excluded();" "Built use of excluded function. This should not be possible.")
+  shared_build_fail("return libshared_not_exported();" "Built use of not-exported function. This should not be possible.")
+else()
+  shared_build_pass("LibsharedNotExported l; return l.libshared();" "Built use of not-exported class method.")
+  shared_build_pass("LibsharedNotExported l; return l.libshared_not_exported();" "Built use of not-exported class method.")
+  shared_build_pass("LibsharedNotExported l; return l.libshared_excluded();" "Built use of not-exported class method.")
+  shared_build_pass("LibsharedExcluded l; return l.libshared();" "Built use of excluded class method.")
+  shared_build_pass("LibsharedExcluded l; return l.libshared_not_exported();" "Built use of excluded class method.")
+  shared_build_pass("LibsharedExcluded l; return l.libshared_excluded();" "Built use of excluded class method.")
+
+  shared_build_pass("return libshared_excluded();" "Built use of excluded function.")
+  shared_build_pass("return libshared_not_exported();" "Built use of not-exported function.")
+endif()
--- a/Tests/Module/GenerateExportHeader/libstatic/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/libstatic/CMakeLists.txt
@ -0,0 +1,8 @@
+
+project(libstatic)
+
+# Show that the export header has no effect on a static library.
+
+add_library(libstatic STATIC libstatic.cpp)
+
+generate_export_header(libstatic)
--- a/Tests/Module/GenerateExportHeader/libstatic/libstatic.cpp
+++ b/Tests/Module/GenerateExportHeader/libstatic/libstatic.cpp
@ -0,0 +1,87 @@
+
+#include "libstatic.h"
+
+int Libstatic::libstatic() const
+{
+  return 0;
+}
+
+int Libstatic::libstatic_exported() const
+{
+  return 0;
+}
+
+int Libstatic::libstatic_deprecated() const
+{
+  return 0;
+}
+
+int Libstatic::libstatic_not_exported() const {
+  return 0;
+}
+
+int Libstatic::libstatic_excluded() const {
+  return 0;
+}
+
+int LibstaticNotExported::libstatic() const
+{
+  return 0;
+}
+
+int LibstaticNotExported::libstatic_exported() const
+{
+  return 0;
+}
+
+int LibstaticNotExported::libstatic_deprecated() const
+{
+  return 0;
+}
+
+int LibstaticNotExported::libstatic_not_exported() const {
+  return 0;
+}
+
+int LibstaticNotExported::libstatic_excluded() const {
+  return 0;
+}
+
+int LibstaticExcluded::libstatic() const
+{
+  return 0;
+}
+
+int LibstaticExcluded::libstatic_exported() const
+{
+  return 0;
+}
+
+int LibstaticExcluded::libstatic_deprecated() const
+{
+  return 0;
+}
+
+int LibstaticExcluded::libstatic_not_exported() const {
+  return 0;
+}
+
+int LibstaticExcluded::libstatic_excluded() const {
+  return 0;
+}
+
+int libstatic_exported() {
+  return 0;
+}
+
+int libstatic_deprecated() {
+  return 0;
+}
+
+int libstatic_not_exported() {
+  return 0;
+}
+
+int libstatic_excluded() {
+  return 0;
+}
--- a/Tests/Module/GenerateExportHeader/libstatic/libstatic.h
+++ b/Tests/Module/GenerateExportHeader/libstatic/libstatic.h
@ -0,0 +1,54 @@
+
+#ifndef LIBSTATIC_H
+#define LIBSTATIC_H
+
+#include "libstatic_export.h"
+
+class LIBSTATIC_EXPORT Libstatic {
+public:
+  int libstatic() const;
+
+  int libstatic_exported() const;
+
+  int LIBSTATIC_DEPRECATED libstatic_deprecated() const;
+
+  int libstatic_not_exported() const;
+
+  int LIBSTATIC_NO_EXPORT libstatic_excluded() const;
+};
+
+class LibstaticNotExported {
+public:
+  int libstatic() const;
+
+  int LIBSTATIC_EXPORT libstatic_exported() const;
+
+  int LIBSTATIC_DEPRECATED libstatic_deprecated() const;
+
+  int libstatic_not_exported() const;
+
+  int LIBSTATIC_NO_EXPORT libstatic_excluded() const;
+};
+
+class LIBSTATIC_NO_EXPORT LibstaticExcluded {
+public:
+  int libstatic() const;
+
+  int LIBSTATIC_EXPORT libstatic_exported() const;
+
+  int LIBSTATIC_DEPRECATED libstatic_deprecated() const;
+
+  int libstatic_not_exported() const;
+
+  int LIBSTATIC_NO_EXPORT libstatic_excluded() const;
+};
+
+LIBSTATIC_EXPORT int libstatic_exported();
+
+LIBSTATIC_DEPRECATED_EXPORT int libstatic_deprecated();
+
+int libstatic_not_exported();
+
+int LIBSTATIC_NO_EXPORT libstatic_excluded();
+
+#endif
--- a/Tests/Module/GenerateExportHeader/libstatictest/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/libstatictest/CMakeLists.txt
@ -0,0 +1,18 @@
+
+macro(static_build_pass Source Message)
+  build_pass("libstatic.h" "libstatic" "libstatic" "${Source}" ${Message})
+endmacro()
+
+macro(static_build_fail Source Message)
+  build_fail("libstatic.h" "libstatic" "libstatic" "${Source}" ${Message})
+endmacro()
+
+static_build_pass("Libstatic l; return l.libstatic_exported();" "Failed to build exported.")
+
+# if (COMPILER_HAS_DEPRECATED)
+#   static_build_fail("Libstatic l; return l.libstatic_deprecated();" "Built use of deprecated class method. This should not be possible.")
+#   static_build_fail("libstatic_deprecated();" "Built use of deprecated function. This should not be possible.")
+# else()
+#   static_build_pass("Libstatic l; return l.libstatic_deprecated();" "Built use of deprecated class method. This should not be possible.")
+#   static_build_pass("libstatic_deprecated();" "Built use of deprecated function. This should not be possible.")
+# endif()
--- a/Tests/Module/GenerateExportHeader/override_symbol/CMakeLists.txt
+++ b/Tests/Module/GenerateExportHeader/override_symbol/CMakeLists.txt
@ -0,0 +1,11 @@
+project(override_symbol)
+
+add_library(somelib SHARED someclass.cpp)
+
+set_target_properties(somelib PROPERTIES DEFINE_SYMBOL SOMELIB_MAKEDLL)
+
+generate_export_header(somelib)
+
+add_executable(consumer main.cpp)
+
+target_link_libraries(consumer somelib)
--- a/Tests/Module/GenerateExportHeader/override_symbol/main.cpp
+++ b/Tests/Module/GenerateExportHeader/override_symbol/main.cpp
@ -0,0 +1,9 @@
+
+#include "someclass.h"
+
+int main(int, char**)
+{
+  SomeClass sc;
+  sc.someMethod();
+  return 0;
+}
--- a/Tests/Module/GenerateExportHeader/override_symbol/someclass.cpp
+++ b/Tests/Module/GenerateExportHeader/override_symbol/someclass.cpp
@ -0,0 +1,7 @@
+
+#include "someclass.h"
+
+void SomeClass::someMethod() const
+{
+
+}
--- a/Tests/Module/GenerateExportHeader/override_symbol/someclass.h
+++ b/Tests/Module/GenerateExportHeader/override_symbol/someclass.h
@ -0,0 +1,8 @@
+
+#include "somelib_export.h"
+
+class SOMELIB_EXPORT SomeClass
+{
+public:
+  void someMethod() const;
+};